keifu: init at 0.3.0 (#521618)

maintainers/maintainer-list.nix

@@ -28690,6 +28690,12 @@
     github = "usrfriendly";
     githubId = 2502060;
   };
+  usu171 = {
+    email = "usu171@proton.me";
+    github = "Usu171";
+    githubId = 52230991;
+    name = "Usu171";
+  };
   utdemir = {
     email = "me@utdemir.com";
     github = "utdemir";

pkgs/by-name/ke/keifu/package.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  libgit2,
+  openssl,
+  zlib,
+  makeWrapper,
+  gitMinimal,
+  stdenv,
+  libiconv,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "keifu";
+  version = "0.3.0";
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "trasta298";
+    repo = "keifu";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Srw71Rswafu70kKI36dY1PtB4BQhpTYYzqbrWJuvaUM=";
+  };
+
+  cargoHash = "sha256-Ga405TV1uDSZbADrV+3aAeLDRfdPFHzdxxTEDu+f+b4=";
+
+  nativeBuildInputs = [
+    pkg-config
+    makeWrapper
+  ];
+
+  buildInputs = [
+    libgit2
+    openssl
+    zlib
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [ libiconv ];
+
+  env = {
+    OPENSSL_NO_VENDOR = true;
+  };
+
+  postInstall = ''
+    wrapProgram $out/bin/keifu \
+      --prefix PATH : ${lib.makeBinPath [ gitMinimal ]}
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "A TUI tool to visualize Git commit graphs with branch genealogy";
+    homepage = "https://github.com/trasta298/keifu";
+    changelog = "https://github.com/trasta298/keifu/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      usu171
+    ];
+    mainProgram = "keifu";
+    platforms = lib.platforms.unix;
+  };
+})