artichoke: init at 0-unstable-2025-06-01 (#414459)

2025-06-09 23:52:28 +08:00
parent 60e643828c 9ebbf272a7
commit 45b68968a3
1 changed files with 58 additions and 0 deletions
@@ -0,0 +1,58 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  llvmPackages,
+  _experimental-update-script-combinators,
+  unstableGitUpdater,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage {
+  pname = "artichoke";
+  version = "0-unstable-2025-06-01";
+
+  src = fetchFromGitHub {
+    owner = "artichoke";
+    repo = "artichoke";
+    rev = "7c35392d8c7622cd8ab8eccaee73d57633b2b901";
+    hash = "sha256-7YPExT+5F+5MMk/yLfG4Rk8ZDwsYfVKlkvIroFB22No=";
+  };
+
+  cargoHash = "sha256-cN70yYYKhktUoswow63ZXHvfFbXDo1rUrTWm22LluCM=";
+
+  nativeBuildInputs = [
+    rustPlatform.bindgenHook
+  ];
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    runHook preInstallCheck
+
+    stdout="$("$out/bin/artichoke" -e 'puts "Hello World!"')"
+    [[ "$stdout" == 'Hello World!' ]]
+
+    runHook postInstallCheck
+  '';
+
+  passthru = {
+    updateScript = _experimental-update-script-combinators.sequence [
+      (unstableGitUpdater { })
+      (nix-update-script {
+        # Updating `cargoHash`
+        extraArgs = [ "--version=skip" ];
+      })
+    ];
+  };
+
+  meta = {
+    description = "Ruby implementation written in Rust and Ruby";
+    homepage = "https://www.artichokeruby.org/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      kachick
+    ];
+    mainProgram = "artichoke";
+    platforms = with lib.platforms; unix ++ windows;
+  };
+}