nheko: add identicons support (#150487)

pkgs/by-name/nh/nheko/package.nix

@@ -62,6 +62,7 @@ stdenv.mkDerivation rec {
       qt6Packages.qtmultimedia
       qt6Packages.qttools
       qt6Packages.qtwayland
+      qt6Packages.qt-jdenticon
       re2
       spdlog
     ]

pkgs/development/libraries/qt-jdenticon/default.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  qmake,
+  qtbase,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "qt-jdenticon";
+  version = "0.3.0";
+
+  src = fetchFromGitHub {
+    owner = "Nheko-Reborn";
+    repo = "qt-jdenticon";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-Q5M7+XkY+/IS45rcFLYPfbcvQm8LDk4S9gzKigCIM7s=";
+  };
+
+  nativeBuildInputs = [ qmake ];
+  buildInputs = [ qtbase ];
+
+  dontWrapQtApps = true;
+
+  postPatch = ''
+    # Fix plugins dir
+    substituteInPlace QtIdenticon.pro \
+      --replace "\$\$[QT_INSTALL_PLUGINS]" "$out/$qtPluginPrefix"
+  '';
+
+  meta = {
+    description = "Qt plugin for generating highly recognizable identicons";
+    homepage = "https://github.com/Nheko-Reborn/qt-jdenticon";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ unclechu ];
+  };
+})

pkgs/top-level/qt6-packages.nix

@@ -86,6 +86,8 @@ makeScopeWithSplicing' {
 
   qtutilities = callPackage ../development/libraries/qtutilities { };
 
+  qt-jdenticon = callPackage ../development/libraries/qt-jdenticon { };
+
   quazip = callPackage ../development/libraries/quazip { };
 
   qscintilla = callPackage ../development/libraries/qscintilla { };