futility: init at 0-release-R144-16503.B

Signed-off-by: David Wronek <david.wronek@mainlining.org>
2026-03-20 14:37:31 +01:00
parent b2bb460740
commit 3fe7909d82
1 changed files with 55 additions and 0 deletions
@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchgit,
+  openssl,
+  pkg-config,
+  nss,
+}:
+let
+  url = "https://chromium.googlesource.com/chromiumos/platform/vboot_reference";
+  branch = "release-R145-16552.B";
+in
+stdenv.mkDerivation {
+  pname = "futility";
+  version = "0-${branch}";
+
+  src = fetchgit {
+    inherit url;
+    rev = "refs/heads/${branch}";
+    hash = "sha256-LctTKkf8nTVcrErMiAkvSCYkZnBoTYjqxWj0xADi0Q4=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    openssl
+    nss
+  ];
+
+  postPatch = ''
+    patchShebangs ./scripts
+    substituteInPlace ./scripts/getversion.sh \
+      --replace-fail "unknown" "${branch}"
+  '';
+
+  makeFlags = [
+    "UB_DIR=$(out)/bin"
+    "USE_FLASHROM=0"
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [ "HAVE_MACOS=1" ];
+
+  buildFlags = "futil";
+
+  installTargets = "futil_install";
+
+  meta = {
+    homepage = url;
+    description = "ChromeOS firmware utility";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ ungeskriptet ];
+    teams = [ lib.teams.android ];
+    mainProgram = "futility";
+    badPlatforms = lib.platforms.darwin;
+  };
+}