protoc-gen-es: init at 1.10.0

pkgs/by-name/pr/protoc-gen-es/package.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  npm-lockfile-fix,
+}:
+
+buildNpmPackage rec {
+  pname = "protoc-gen-es";
+  version = "1.10.0";
+
+  src = fetchFromGitHub {
+    owner = "bufbuild";
+    repo = "protobuf-es";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-bHl8gqNrTm1+Cnj43RWmrLDUz+G11C4gprEiNOpyOdQ=";
+
+    postFetch = ''
+      ${lib.getExe npm-lockfile-fix} $out/package-lock.json
+    '';
+  };
+
+  npmDepsHash = "sha256-ozkkakfSBycu83gTs8Orhm5Tg8kRSrF/vMJxVnPjhIw=";
+
+  npmWorkspace = "packages/protoc-gen-es";
+
+  preBuild = ''
+    npm run --workspace=packages/protobuf build
+    npm run --workspace=packages/protoplugin build
+  '';
+
+  passthru.updateScript = ./update.sh;
+
+  meta = with lib; {
+    description = "Protobuf plugin for generating ECMAScript code";
+    homepage = "https://github.com/bufbuild/protobuf-es";
+    changelog = "https://github.com/bufbuild/protobuf-es/releases/tag/v${version}";
+    license = licenses.asl20;
+    maintainers = with maintainers; [
+      felschr
+      jtszalay
+    ];
+  };
+}

pkgs/by-name/pr/protoc-gen-es/update.sh

@@ -0,0 +1,30 @@
+#! /usr/bin/env -S nix shell nixpkgs#gnugrep nixpkgs#gnused nixpkgs#coreutils nixpkgs#curl nixpkgs#wget nixpkgs#jq nixpkgs#nix-update nixpkgs#prefetch-npm-deps nixpkgs#npm-lockfile-fix nixpkgs#nodejs --command bash
+
+set -euo pipefail
+
+version="$(
+  curl ${GITHUB_TOKEN:+" -u \":$GITHUB_TOKEN\""} -s "https://api.github.com/repos/bufbuild/protobuf-es/releases" |
+    jq -r 'map(select(.prerelease == false)) | .[0].tag_name' |
+    grep -oP "^v\K.*"
+)"
+url="https://raw.githubusercontent.com/bufbuild/protobuf-es/v$version/"
+
+if [[ "$UPDATE_NIX_OLD_VERSION" == "$version" ]]; then
+  echo "Already up to date!"
+  exit 0
+fi
+
+tmp="$(mktemp -d)"
+trap 'rm -rf -- "$tmp"' EXIT
+
+pushd -- "$tmp"
+wget "$url/package-lock.json"
+npm-lockfile-fix package-lock.json
+npm_hash=$(prefetch-npm-deps package-lock.json)
+popd
+
+pushd "$(dirname "${BASH_SOURCE[0]}")"
+sed -i 's#npmDepsHash = "[^"]*"#npmDepsHash = "'"$npm_hash"'"#' package.nix
+popd
+
+nix-update protoc-gen-es --version "$version"