python3Packages.symbolic_10: init at 10.2.1

required by glitchtip

pkgs/by-name/gl/glitchtip/package.nix

@@ -47,7 +47,7 @@ let
       psycopg
       pydantic
       sentry-sdk
-      symbolic
+      symbolic_10
       user-agents
       uvicorn
       uwsgi-chunked

pkgs/development/python-modules/symbolic/10.nix

@@ -0,0 +1,76 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools-rust,
+  rustPlatform,
+  rustc,
+  cargo,
+  milksnake,
+  cffi,
+  pytestCheckHook,
+  nixosTests,
+}:
+
+buildPythonPackage rec {
+  pname = "symbolic";
+  version = "10.2.1"; # glitchtip currently only works with symbolic 10.x
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "getsentry";
+    repo = "symbolic";
+    tag = version;
+    hash = "sha256-3u4MTzaMwryGpFowrAM/MJOmnU8M+Q1/0UtALJib+9A=";
+    # the `py` directory is not included in the tarball, so we fetch the source via git instead
+    forceFetchGit = true;
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit
+      pname
+      version
+      src
+      postPatch
+      ;
+    hash = "sha256-cpIVzgcxKfEA5oov6/OaXqknYsYZUoduLTn2qIXGL5U=";
+  };
+
+  nativeBuildInputs = [
+    setuptools-rust
+    rustPlatform.cargoSetupHook
+    rustc
+    cargo
+    milksnake
+  ];
+
+  dependencies = [ cffi ];
+
+  postPatch = ''
+    ln -s ${./Cargo.lock} Cargo.lock
+  '';
+
+  preBuild = ''
+    cd py
+  '';
+
+  preCheck = ''
+    cd ..
+  '';
+
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  pytestFlagsArray = [ "py" ];
+
+  pythonImportsCheck = [ "symbolic" ];
+
+  passthru.tests = { inherit (nixosTests) glitchtip; };
+
+  meta = {
+    description = "Python library for dealing with symbol files and more";
+    homepage = "https://github.com/getsentry/symbolic";
+    changelog = "https://github.com/getsentry/symbolic/blob/${version}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ defelo ];
+  };
+}

pkgs/development/python-modules/symbolic/default.nix

@@ -9,12 +9,11 @@
   milksnake,
   cffi,
   pytestCheckHook,
-  nixosTests,
 }:
 
 buildPythonPackage rec {
   pname = "symbolic";
-  version = "12.14.1"; # glitchtip currently only works with symbolic 10.x
+  version = "12.14.1";
   pyproject = true;
 
   src = fetchFromGitHub {
@@ -22,16 +21,12 @@ buildPythonPackage rec {
     repo = "symbolic";
     tag = version;
     hash = "sha256-u3nEYvnt2P+W/0zYctikMgdkalej86eCYhfWj9LW4pU=";
-    # for some reason the `py` directory in the tarball is empty, so we fetch the source via git instead
+    # the `py` directory is not included in the tarball, so we fetch the source via git instead
     forceFetchGit = true;
   };
 
   cargoDeps = rustPlatform.fetchCargoVendor {
-    inherit
-      pname
-      version
-      src
-      ;
+    inherit pname version src;
     hash = "sha256-X8IjmSQD32bougiUFyuk8OOGIzIQgk/TjVM5bgUey5M=";
   };
 
@@ -59,8 +54,6 @@ buildPythonPackage rec {
 
   pythonImportsCheck = [ "symbolic" ];
 
-  passthru.tests = { inherit (nixosTests) glitchtip; };
-
   meta = {
     description = "Python library for dealing with symbol files and more";
     homepage = "https://github.com/getsentry/symbolic";

pkgs/top-level/python-packages.nix

@@ -16788,6 +16788,8 @@ self: super: with self; {
 
   symbolic = callPackage ../development/python-modules/symbolic { };
 
+  symbolic_10 = callPackage ../development/python-modules/symbolic/10.nix { };
+
   symengine = callPackage ../development/python-modules/symengine { inherit (pkgs) symengine; };
 
   symfc = callPackage ../development/python-modules/symfc { };