vclab-nexus: init at 2025.05

Co-authored-by: Sandro <sandro.jaeckel@gmail.com>

pkgs/by-name/li/lib3mf/package.nix

@@ -100,6 +100,7 @@ stdenv.mkDerivation (finalAttrs: {
       --replace-fail "CRYPTO_cleanup_all_ex_data();" ""
 
     # Fix CMake export
+    # ref https://github.com/3MFConsortium/lib3mf/pull/434
     substituteInPlace cmake/lib3mfConfig.cmake \
       --replace-fail "$""{LIB3MF_ROOT_DIR}/include" "$""{LIB3MF_ROOT_DIR}/include/lib3mf" \
       --replace-fail "$""{LIB3MF_ROOT_DIR}/lib" "$out/lib"

pkgs/by-name/vc/vclab-nexus/package.nix

@@ -0,0 +1,72 @@
+{
+  lib,
+
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+
+  # nativeBuildInputs
+  cmake,
+  libsForQt5,
+
+  # buildInputs
+  corto,
+  glew,
+  llvmPackages,
+  vcg,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "nexus";
+  version = "2025.05";
+
+  src = fetchFromGitHub {
+    owner = "cnr-isti-vclab";
+    repo = "nexus";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-lC3nKQJwkixwGzPP/oS0J+WIFgYqky6NaXu9bX28+3I=";
+  };
+
+  outputs = [
+    "out"
+    "bin"
+  ];
+
+  patches = [
+    # CMake: install lib & exports
+    # ref. https://github.com/cnr-isti-vclab/nexus/pull/173
+    # merged upstream
+    (fetchpatch {
+      url = "https://github.com/cnr-isti-vclab/nexus/commit/141ba17059f3680a74ce1178ed4245412f76061f.patch";
+      hash = "sha256-iY84QIpliC1BIImI/6S6E6fQwMKPmmTiwouCXW6wLuM=";
+    })
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    libsForQt5.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    corto
+    glew
+    libsForQt5.qtbase
+    vcg
+  ]
+  ++ lib.optionals stdenv.cc.isClang [
+    llvmPackages.openmp
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_NXS_VIEW" (!stdenv.hostPlatform.isDarwin))
+  ];
+
+  meta = {
+    description = "Library for creation and visualization of a batched multiresolution mesh";
+    homepage = "https://github.com/cnr-isti-vclab/nexus";
+    license = lib.licenses.gpl2;
+    maintainers = with lib.maintainers; [ nim65s ];
+    mainProgram = "nxsview";
+    platforms = lib.platforms.unix ++ lib.platforms.windows;
+  };
+})