python3.pkgs.pyside6: init at 6.5.0

pkgs/development/python-modules/pyside6/default.nix

@@ -0,0 +1,77 @@
+{ lib
+, stdenv
+, cmake
+, ninja
+, qt6
+, python
+, shiboken6
+, libxcrypt
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pyside6";
+
+  inherit (shiboken6) version src;
+
+  sourceRoot = "pyside-setup-everywhere-src-${lib.versions.majorMinor version}/sources/${pname}";
+
+  postPatch = ''
+    # Don't ignore optional Qt modules
+    substituteInPlace cmake/PySideHelpers.cmake \
+      --replace \
+        'string(FIND "''${_module_dir}" "''${_core_abs_dir}" found_basepath)' \
+        'set (found_basepath 0)'
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    python
+  ];
+
+  buildInputs = with qt6; [
+    # required
+    qtbase
+    # optional
+    qt3d
+    qtcharts
+    qtconnectivity
+    qtdatavis3d
+    qtdeclarative
+    qthttpserver
+    qtmultimedia
+    qtnetworkauth
+    qtquick3d
+    qtremoteobjects
+    qtscxml
+    qtsensors
+    qtspeech
+    qtsvg
+    qttools
+    qtwebchannel
+    qtwebengine
+    qtwebsockets
+  ] ++ lib.optionals (python.pythonOlder "3.9") [
+    # see similar issue: 202262
+    # libxcrypt is required for crypt.h for building older python modules
+    libxcrypt
+  ];
+
+  propagatedBuildInputs = [
+    shiboken6
+  ];
+
+  cmakeFlags = [
+    "-DBUILD_TESTS=OFF"
+  ];
+
+  dontWrapQtApps = true;
+
+  meta = with lib; {
+    description = "Python bindings for Qt";
+    license = with licenses; [ lgpl3Only gpl2Only gpl3Only ];
+    homepage = "https://wiki.qt.io/Qt_for_Python";
+    maintainers = with maintainers; [ gebner Enzime ];
+    broken = stdenv.isDarwin;
+  };
+}

pkgs/top-level/python-packages.nix

@@ -9133,6 +9133,10 @@ self: super: with self; {
     inherit (pkgs) cmake ninja qt5;
   });
 
+  pyside6 = toPythonModule (callPackage ../development/python-modules/pyside6 {
+    inherit (pkgs) cmake ninja qt6;
+  });
+
   pyside = callPackage ../development/python-modules/pyside {
     inherit (pkgs) mesa;
   };