chuck: 1.4.2.0 -> 1.5.5.6, refactor, move to pkgs/by-name

pkgs/applications/audio/chuck/default.nix

@@ -1,51 +0,0 @@
-{
-  stdenv,
-  lib,
-  fetchurl,
-  alsa-lib,
-  bison,
-  flex,
-  libsndfile,
-  which,
-  DarwinTools,
-  xcbuild,
-}:
-
-stdenv.mkDerivation rec {
-  version = "1.4.2.0";
-  pname = "chuck";
-
-  src = fetchurl {
-    url = "http://chuck.cs.princeton.edu/release/files/chuck-${version}.tgz";
-    sha256 = "sha256-hIwsC9rYgXWSTFqUufKGqoT0Gnsf4nR4KQ0iSVbj8xg=";
-  };
-
-  nativeBuildInputs = [
-    flex
-    bison
-    which
-  ]
-  ++ lib.optionals stdenv.hostPlatform.isDarwin [
-    DarwinTools
-    xcbuild
-  ];
-
-  buildInputs = [ libsndfile ] ++ lib.optional (!stdenv.hostPlatform.isDarwin) alsa-lib;
-
-  patches = [ ./darwin-limits.patch ];
-
-  makeFlags = [
-    "-C src"
-    "DESTDIR=$(out)/bin"
-  ];
-  buildFlags = [ (if stdenv.hostPlatform.isDarwin then "mac" else "linux-alsa") ];
-
-  meta = {
-    description = "Programming language for real-time sound synthesis and music creation";
-    homepage = "http://chuck.cs.princeton.edu";
-    license = lib.licenses.gpl2;
-    platforms = lib.platforms.unix;
-    maintainers = with lib.maintainers; [ ftrvxmtrx ];
-    mainProgram = "chuck";
-  };
-}

pkgs/by-name/ch/chuck/package.nix

@@ -0,0 +1,70 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  bison,
+  flex,
+  pkg-config,
+  darwin,
+  xcbuild,
+  libsndfile,
+  alsa-lib,
+  libjack2,
+  libpulseaudio,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  version = "1.5.5.6";
+  pname = "chuck";
+
+  src = fetchFromGitHub {
+    owner = "ccrma";
+    repo = "chuck";
+    tag = "chuck-${finalAttrs.version}";
+    hash = "sha256-KBmMpycNCjRZJPdRR3HG5nqHQhhVOENciRpiQ7buyok=";
+  };
+
+  nativeBuildInputs = [
+    bison
+    flex
+    pkg-config
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    darwin.DarwinTools
+    xcbuild
+  ];
+
+  buildInputs = [
+    libsndfile
+  ]
+  ++ lib.optionals (!stdenv.hostPlatform.isDarwin) [
+    alsa-lib
+    libpulseaudio
+    libjack2
+  ];
+
+  makeFlags = [
+    "-C src"
+    "DESTDIR=$(out)/bin"
+    # fix hardcoded gcc
+    "CC=cc"
+    "CXX=c++"
+  ];
+  buildFlags = [ (if stdenv.hostPlatform.isDarwin then "mac" else "linux-all") ];
+
+  passthru.updateScript = nix-update-script { extraArgs = [ "--version-regex=chuck-(.*)" ]; };
+
+  meta = {
+    description = "Programming language for real-time sound synthesis and music creation";
+    homepage = "http://chuck.cs.princeton.edu";
+    license = with lib.licenses; [
+      gpl2Plus
+      # or
+      mit
+    ];
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ ftrvxmtrx ];
+    mainProgram = "chuck";
+  };
+})

pkgs/top-level/all-packages.nix

@@ -10347,10 +10347,6 @@ with pkgs;
 
   chromium = callPackage ../applications/networking/browsers/chromium (config.chromium or { });
 
-  chuck = callPackage ../applications/audio/chuck {
-    inherit (darwin) DarwinTools;
-  };
-
   clipgrab = libsForQt5.callPackage ../applications/video/clipgrab { };
 
   cni = callPackage ../applications/networking/cluster/cni { };