collada-dom: init at 2.5.1

Previously removed due to being unmaintained, this commit
adds collada-dom back to Nixpkgs, as opencollada proved an
insufficient replacement to it. The new upstream is slightly
more modern than the previous one.

Co-authored-by: Marius David <marius@mariusdavid.fr>
Signed-off-by: Fernando Rodrigues <alpha@sigmasquadron.net>

pkgs/by-name/co/collada-dom/package.nix

@@ -0,0 +1,54 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  boost,
+  libxml2,
+  minizip,
+  readline,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "collada-dom";
+  version = "2.5.1";
+
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  src = fetchFromGitHub {
+    owner = "Gepetto";
+    repo = "collada-dom";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-DYdqrwRIrVq0BQqZB0vtZzADteJGVaJtFC5kC/cD250=";
+  };
+
+  postInstall = ''
+    ln -s $out/include/*/* $out/include
+  '';
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [
+    boost
+    libxml2
+    minizip
+    readline
+  ];
+
+  meta = {
+    description = "API that provides a C++ object representation of a COLLADA XML instance document";
+    longDescription = "This is a fork of [rdiankov/collada-dom](https://github.com/rdiankov/collada-dom) which has been unmaintained for six years.";
+    homepage = "https://github.com/Gepetto/collada-dom";
+    changelog = "https://github.com/Gepetto/collada-dom/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      sigmasquadron
+      marius851000
+    ];
+    platforms = lib.platforms.all;
+
+    # Fails to build.
+    badPlatforms = lib.platforms.darwin;
+  };
+})

pkgs/top-level/aliases.nix

@@ -632,7 +632,6 @@ mapAliases {
   code-browser-gtk = throw "'code-browser-gtk' has been removed, as it was broken since 22.11"; # Added 2025-08-22
   code-browser-gtk2 = throw "'code-browser-gtk2' has been removed, as it was broken since 22.11"; # Added 2025-08-22
   code-browser-qt = throw "'code-browser-qt' has been removed, as it was broken since 22.11"; # Added 2025-08-22
-  collada-dom = opencollada; # added 2024-02-21
   collada2gltf = throw "collada2gltf has been removed from Nixpkgs, as it has been unmaintained upstream for 5 years and does not build with supported GCC versions"; # Addd 2025-08-08
   colloid-kde = throw "'colloid-kde' has been removed, as it is only compatible with Plasma 5, which is EOL"; # Added 2025-08-20
   colorpicker = throw "'colorpicker' has been removed due to lack of maintenance upstream. Consider using 'xcolor', 'gcolor3', 'eyedropper' or 'gpick' instead"; # Added 2024-10-19