gitingest: init at 0.1.3 (#384545)

pkgs/by-name/gi/gitingest/package.nix

@@ -0,0 +1,3 @@
+{ python3Packages }:
+
+python3Packages.toPythonApplication python3Packages.gitingest

pkgs/development/python-modules/gitingest/default.nix

@@ -0,0 +1,81 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # Dependencies
+  setuptools,
+  click,
+  fastapi,
+  python-dotenv,
+  slowapi,
+  starlette,
+  tiktoken,
+  tomli,
+  uvicorn,
+
+  # Tests
+  httpx,
+  jinja2,
+  pytestCheckHook,
+  python-multipart,
+}:
+
+buildPythonPackage rec {
+  pname = "gitingest";
+  version = "0.1.3";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "cyclotruc";
+    repo = "gitingest";
+    tag = "v${version}";
+    hash = "sha256-RGrenW0modLH9h5pQOexPvEDQ9Bczoj1qInYmgUoGdo=";
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  pythonRelaxDeps = [
+    "fastapi"
+  ];
+
+  dependencies = [
+    click
+    fastapi
+    python-dotenv
+    slowapi
+    starlette
+    tiktoken
+    tomli
+    uvicorn
+  ];
+
+  pythonImportsCheck = [
+    "gitingest"
+  ];
+
+  nativeCheckInputs = [
+    httpx
+    jinja2
+    pytestCheckHook
+    python-multipart
+  ];
+
+  disabledTests = [
+    # Tests require network
+    "test_cli_with_default_options"
+    "test_cli_with_options"
+    "test_run_ingest_query"
+  ];
+
+  meta = {
+    changelog = "https://github.com/cyclotruc/gitingest/releases/tag/v${version}";
+    description = "Replace 'hub' with 'ingest' in any github url to get a prompt-friendly extract of a codebase";
+    homepage = "https://github.com/cyclotruc/gitingest";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ drupol ];
+    mainProgram = "gitingest";
+  };
+}

pkgs/development/python-modules/slowapi/default.nix

@@ -49,6 +49,9 @@ buildPythonPackage rec {
     # AssertionError: Regex pattern 'parameter `request` must be an instance of starlette.requests.Request' does not match 'This portal is not running'.
     "test_endpoint_request_param_invalid"
     "test_endpoint_response_param_invalid"
+    # AssertionError: assert '1740326049.9886339' == '1740326049'
+    "test_headers_no_breach"
+    "test_headers_breach"
   ] ++ lib.optionals (pythonAtLeast "3.10") [ "test_multiple_decorators" ];
 
   pythonImportsCheck = [ "slowapi" ];

pkgs/top-level/python-packages.nix

@@ -5354,6 +5354,8 @@ self: super: with self; {
 
   github3-py = callPackage ../development/python-modules/github3-py { };
 
+  gitingest = callPackage ../development/python-modules/gitingest { };
+
   gitignore-parser = callPackage ../development/python-modules/gitignore-parser { };
 
   gitlike-commands = callPackage ../development/python-modules/gitlike-commands { };