Merge pull request #229009 from MatthewCroughan/mc/therion

therion: init at 6.1.7

pkgs/applications/misc/therion/default.nix

@@ -0,0 +1,97 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, pkg-config
+, perl
+, tcl
+, tcllib
+, tk
+, expat
+, bwidget
+, python3
+, texlive
+, survex
+, makeWrapper
+, fmt
+, proj
+, wxGTK32
+, vtk
+, freetype
+, libjpeg
+, gettext
+, libGL
+, libGLU
+, sqlite
+, libtiff
+, curl
+, tkimg
+}:
+
+stdenv.mkDerivation rec {
+  pname = "therion";
+  version = "6.1.7";
+
+  src = fetchFromGitHub {
+    owner = "therion";
+    repo = "therion";
+    rev = "v${version}";
+    hash = "sha256-q+p1akGfzBeZejeYiJ8lrSbEIMTsX5YuIG/u35oh0JI=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    perl
+    python3
+    texlive.combined.scheme-tetex
+    makeWrapper
+    tcl.tclPackageHook
+  ];
+
+  preConfigure = ''
+    export OUTDIR=$out
+  '';
+
+  cmakeFlags = [
+    "-DBUILD_THBOOK=OFF"
+  ];
+
+  buildInputs = [
+    expat
+    tkimg
+    proj
+    wxGTK32
+    vtk
+    tk
+    freetype
+    libjpeg
+    gettext
+    libGL
+    libGLU
+    sqlite
+    libtiff
+    curl
+    fmt
+    tcl
+    tcllib
+    bwidget
+  ];
+
+  fixupPhase = ''
+    runHook preFixup
+    wrapProgram $out/bin/therion \
+      --prefix PATH : ${lib.makeBinPath [ survex texlive.combined.scheme-tetex ]}
+    wrapProgram $out/bin/xtherion \
+      --prefix PATH : ${lib.makeBinPath [ tk ]}
+    runHook postFixup
+  '';
+
+  meta = with lib; {
+    description = "Therion – cave surveying software";
+    homepage = "https://therion.speleo.sk/";
+    changelog = "https://github.com/therion/therion/blob/${src.rev}/CHANGES";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ matthewcroughan ];
+  };
+}

pkgs/development/libraries/tkimg/default.nix

@@ -0,0 +1,28 @@
+{ lib, fetchsvn, tcl, tcllib, tk, xorg }:
+
+tcl.mkTclDerivation rec {
+  pname = "tkimg";
+  version = "623";
+
+  src = fetchsvn {
+    url = "svn://svn.code.sf.net/p/tkimg/code/trunk";
+    rev = version;
+    sha256 = "sha256-6GlkqYxXmMGjiJTZS2fQNVSimcKc1BZ/lvzvtkhty+o=";
+  };
+
+  configureFlags = [
+    "--with-tcl=${tcl}/lib"
+    "--with-tk=${tk}/lib"
+    "--with-tkinclude=${tk.dev}/include"
+  ];
+
+  buildInputs = [ xorg.libX11 tcllib ];
+
+  meta = {
+    homepage = "https://sourceforge.net/projects/tkimg/";
+    description = "The Img package adds several image formats to Tcl/Tk";
+    maintainers = with lib.maintainers; [ matthewcroughan ];
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -24064,6 +24064,8 @@ with pkgs;
   tk-8_6 = callPackage ../development/libraries/tk/8.6.nix { };
   tk-8_5 = callPackage ../development/libraries/tk/8.5.nix { tcl = tcl-8_5; };
 
+  tkimg = callPackage ../development/libraries/tkimg { };
+
   tkrzw = callPackage ../development/libraries/tkrzw { };
 
   tl-expected = callPackage ../development/libraries/tl-expected { };
@@ -39406,6 +39408,8 @@ with pkgs;
 
   thermald = callPackage ../tools/system/thermald { };
 
+  therion = callPackage ../applications/misc/therion { };
+
   throttled = callPackage ../tools/system/throttled { };
 
   thinkfan = callPackage ../tools/system/thinkfan { };