Merge pull request #189542 from foo-dogsquared/add-gradience-app

pkgs/applications/misc/gradience/default.nix

@@ -0,0 +1,80 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, wrapGAppsHook4
+, meson
+, ninja
+, pkg-config
+, glib
+, desktop-file-utils
+, gettext
+, librsvg
+, blueprint-compiler
+, python3Packages
+, sassc
+, appstream-glib
+, libadwaita
+, libportal
+, libportal-gtk4
+, libsoup_3
+, gobject-introspection
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "gradience";
+  version = "0.4.1";
+
+  src = fetchFromGitHub {
+    owner = "GradienceTeam";
+    repo = "Gradience";
+    # See https://github.com/GradienceTeam/Gradience/releases/tag/0.4.1-patch1
+    rev = "0.4.1-patch1";
+    sha256 = "sha256-5jloFbimJC4jP1C1uS8a9VlqyR5qqDuqcKvUXwr9SjY=";
+  };
+
+  format = "other";
+  dontWrapGApps = true;
+
+  nativeBuildInputs = [
+    appstream-glib
+    blueprint-compiler
+    desktop-file-utils
+    gettext
+    glib
+    gobject-introspection
+    meson
+    ninja
+    pkg-config
+    wrapGAppsHook4
+    sassc
+  ];
+
+  buildInputs = [
+    libadwaita
+    libportal
+    libportal-gtk4
+    librsvg
+    libsoup_3
+  ];
+
+  propagatedBuildInputs = with python3Packages; [
+    anyascii
+    jinja2
+    lxml
+    material-color-utilities
+    pygobject3
+    svglib
+    yapsy
+  ];
+
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/GradienceTeam/Gradience";
+    description = "Customize libadwaita and GTK3 apps (with adw-gtk3)";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ foo-dogsquared ];
+  };
+}

pkgs/development/python-modules/material-color-utilities/default.nix

@@ -0,0 +1,28 @@
+{ stdenv, lib, buildPythonPackage, fetchPypi, pillow, regex }:
+
+buildPythonPackage rec {
+  pname = "material-color-utilities-python";
+  version = "0.1.5";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-PG8C585wWViFRHve83z3b9NijHyV+iGY2BdMJpyVH64=";
+  };
+
+  propagatedBuildInputs = [
+    pillow
+    regex
+  ];
+
+  # No tests implemented.
+  doCheck = false;
+
+  pythonImportsCheck = [ "material_color_utilities_python" ];
+
+  meta = with lib; {
+    homepage = "https://pypi.org/project/material_color_utilities_python";
+    description = "Python port of material_color_utilities used for Material You colors";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ foo-dogsquared ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -8026,6 +8026,8 @@ with pkgs;
 
   grafterm = callPackage ../tools/misc/grafterm { };
 
+  gradience = callPackage ../applications/misc/gradience { };
+
   grafx2 = callPackage ../applications/graphics/grafx2 { };
 
   grails = callPackage ../development/web/grails { jdk = null; };

pkgs/top-level/python-packages.nix

@@ -5880,6 +5880,8 @@ self: super: with self; {
 
   mat2 = callPackage ../development/python-modules/mat2 { };
 
+  material-color-utilities = callPackage ../development/python-modules/material-color-utilities { };
+
   matchpy = callPackage ../development/python-modules/matchpy { };
 
   mathlibtools = callPackage ../development/python-modules/mathlibtools { };