budgie-systemmonitor-applet: init at 0.2.1 (#370756)

pkgs/by-name/bu/budgie-systemmonitor-applet/install-schemas-to-datadir.patch

@@ -0,0 +1,13 @@
+diff --git a/meson.build b/meson.build
+index f63bdec..2de3778 100644
+--- a/meson.build
++++ b/meson.build
+@@ -52,7 +52,7 @@ add_project_arguments(
+ LIB_INSTALL_DIR = join_paths(libdir, 'budgie-desktop', 'plugins', meson.project_name())
+ 
+ install_data('schema/com.prateekmedia.systemmonitor.gschema.xml',
+-    install_dir: '/usr/share/glib-2.0/schemas'
++    install_dir: join_paths(datadir, 'glib-2.0/schemas')
+ )
+ 
+ subdir('icons')

pkgs/by-name/bu/budgie-systemmonitor-applet/package.nix

@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  budgie-desktop,
+  fetchFromGitHub,
+  glib,
+  gtk3,
+  libgee,
+  libgtop,
+  libpeas,
+  meson,
+  ninja,
+  nix-update-script,
+  pkg-config,
+  vala,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "budgie-systemmonitor-applet";
+  version = "0.2.1";
+
+  src = fetchFromGitHub {
+    owner = "prateekmedia";
+    repo = "budgie-systemmonitor-applet";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-OWGy2LokpMOW4ZR3K+Bym7i88xQAJqWO43Pu7SjxRSw=";
+  };
+
+  # Remove if/when https://github.com/prateekmedia/budgie-systemmonitor-applet/pull/3 is merged
+  patches = [ ./install-schemas-to-datadir.patch ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    glib # For `glib-compile-schemas`
+    meson
+    ninja
+    pkg-config
+    vala
+  ];
+
+  buildInputs = [
+    budgie-desktop
+    glib
+    gtk3
+    libgee
+    libgtop
+    libpeas
+  ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Budgie applet to show cpu frequency, ram, swap, network and uptime";
+    homepage = "https://github.com/prateekmedia/budgie-systemmonitor-applet";
+    changelog = "https://github.com/prateekmedia/budgie-systemmonitor-applet/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = lib.teams.budgie.members;
+    platforms = lib.platforms.linux;
+  };
+})