mcporter: init at 0.7.3

pkgs/by-name/mc/mcporter/package.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  nodejs,
+  fetchPnpmDeps,
+  pnpmConfigHook,
+  pnpm,
+  npmHooks,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mcporter";
+  version = "0.7.3";
+
+  src = fetchFromGitHub {
+    owner = "steipete";
+    repo = "mcporter";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-x/2Ln6kohj59RSJgctWlYKckmGbWjY2ryPaLhoj0Q48=";
+  };
+
+  pnpmDeps = fetchPnpmDeps {
+    inherit (finalAttrs) pname version src;
+    fetcherVersion = 2;
+    hash = "sha256-0nc+jYANd95/R+BrkGRHcdqw9/RqMja88qkVvHtj1W4=";
+  };
+
+  nativeBuildInputs = [
+    nodejs
+    pnpmConfigHook
+    pnpm
+    npmHooks.npmInstallHook
+  ];
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm run build
+
+    runHook postBuild
+  '';
+
+  dontNpmPrune = true;
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "TypeScript runtime and CLI for connecting to configured Model Context Protocol servers";
+    homepage = "https://github.com/steipete/mcporter";
+    changelog = "https://github.com/steipete/mcporter/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ mkg20001 ];
+    mainProgram = "mcporter";
+  };
+})