hyprpanel: drop (#544274)

pkgs/by-name/hy/hyprpanel/package.nix

@@ -1,142 +0,0 @@
-{
-  lib,
-  config,
-  ags,
-  astal,
-  awww,
-  bluez,
-  bluez-tools,
-  brightnessctl,
-  btop,
-  dart-sass,
-  fetchFromGitHub,
-  glib,
-  glib-networking,
-  gnome-bluetooth,
-  gpu-screen-recorder,
-  gpustat,
-  grimblast,
-  gtksourceview3,
-  gvfs,
-  hyprpicker,
-  libgtop,
-  libnotify,
-  libsoup_3,
-  matugen,
-  networkmanager,
-  nix-update-script,
-  python3,
-  pywal16,
-  stdenv,
-  upower,
-  wireplumber,
-  wl-clipboard,
-  writeShellScript,
-  writeShellScriptBin,
-
-  enableCuda ? config.cudaSupport,
-}:
-
-let
-  # TODO: Remove once hyprpanel updates to use `awww`
-  swww-compat = writeShellScriptBin "swww" ''
-    exec awww "$@"
-  '';
-  swww-daemon-compat = writeShellScriptBin "swww-daemon" ''
-    exec awww-daemon "$@"
-  '';
-in
-
-ags.bundle {
-  pname = "hyprpanel";
-  version = "0-unstable-2026-04-23";
-
-  __structuredAttrs = true;
-  strictDeps = true;
-
-  src = fetchFromGitHub {
-    owner = "Jas-SinghFSU";
-    repo = "HyprPanel";
-    rev = "1961ba86ad5ab880beb639e5454054b2b5037e0d";
-    hash = "sha256-QowlCOrE4jGOTDCUCEx/E8gHjqSx3r25y7v4dEBpBhk=";
-  };
-
-  # keep in sync with https://github.com/Jas-SinghFSU/HyprPanel/blob/master/flake.nix#L42
-  dependencies = [
-    astal.apps
-    astal.battery
-    astal.bluetooth
-    astal.cava
-    astal.hyprland
-    astal.mpris
-    astal.network
-    astal.notifd
-    astal.powerprofiles
-    astal.tray
-    astal.wireplumber
-
-    awww
-    bluez
-    bluez-tools
-    brightnessctl
-    btop
-    dart-sass
-    glib
-    gnome-bluetooth
-    grimblast
-    gtksourceview3
-    gvfs
-    hyprpicker
-    libgtop
-    libnotify
-    libsoup_3
-    matugen
-    networkmanager
-    pywal16
-    swww-compat
-    swww-daemon-compat
-    upower
-    wireplumber
-    wl-clipboard
-    (python3.withPackages (
-      ps:
-      with ps;
-      [
-        dbus-python
-        pygobject3
-      ]
-      ++ lib.optional enableCuda gpustat
-    ))
-  ]
-  ++ (lib.optionals (stdenv.hostPlatform.system == "x86_64-linux") [ gpu-screen-recorder ]);
-
-  passthru.updateScript = nix-update-script { extraArgs = [ "--version=branch" ]; };
-
-  postFixup =
-    let
-      script = writeShellScript "hyprpanel" ''
-        export GIO_EXTRA_MODULES='${glib-networking}/lib/gio/modules'
-        if [ "$#" -eq 0 ]; then
-          exec @out@/bin/.hyprpanel
-        else
-          exec ${astal.io}/bin/astal -i hyprpanel "$*"
-        fi
-      '';
-    in
-    # bash
-    ''
-      mv "$out/bin/hyprpanel" "$out/bin/.hyprpanel"
-      cp '${script}' "$out/bin/hyprpanel"
-      substituteInPlace "$out/bin/hyprpanel" \
-        --replace-fail '@out@' "$out"
-    '';
-
-  meta = {
-    description = "Bar/Panel for Hyprland with extensive customizability";
-    homepage = "https://github.com/Jas-SinghFSU/HyprPanel";
-    license = lib.licenses.mit;
-    maintainers = with lib.maintainers; [ PerchunPak ];
-    mainProgram = "hyprpanel";
-    platforms = lib.platforms.linux;
-  };
-}

pkgs/top-level/aliases.nix

@@ -1055,6 +1055,7 @@ mapAliases {
   hydra_unstable = throw "'hydra_unstable' has been renamed to/replaced by 'hydra'"; # Converted to throw 2025-10-27
   hydraAntLogger = warnAlias "'hydraAntLogger' has been renamed to 'hydra-ant-logger'" hydra-ant-logger; # Added 2026-02-08
   hyprfreeze = warnAlias "'hyprfreeze' has been renamed to 'wl-freeze'" wl-freeze; # Added 2026-04-10
+  hyprpanel = throw "'hyprpanel' has been archived, consider using 'wayle' instead"; # Added 2026-07-21
   i3-gaps = throw "'i3-gaps' has been renamed to/replaced by 'i3'"; # Converted to throw 2025-10-27
   i3lock-pixeled = throw "'i3lock-pixeled' has been unmaintained for several years now."; # Converted to throw 2026-01-24
   ibm-sw-tpm2 = throw "ibm-sw-tpm2 has been removed, as it was broken"; # Added 2025-08-25