qhexedit2: init at 0.8.9

2024-12-05 09:59:29 -08:00
parent 692575b159
commit 07e0e431b1
1 changed files with 66 additions and 0 deletions
@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchpatch,
+  fetchFromGitHub,
+  qt6,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "qhexedit2";
+  version = "0.8.9";
+
+  src = fetchFromGitHub {
+    owner = "Simsys";
+    repo = "qhexedit2";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-qg8dyXwAsTVSx85Ad7UYhr4d1aTRG9QbvC0uyOMcY8g=";
+  };
+
+  postPatch = ''
+    # Replace QPallete::Background with QPallete::Window in all files, since QPallete::Background was removed in Qt 6
+    find . -type f -exec sed -i 's/QPalette::Background/QPalette::Window/g' {} +
+  '';
+
+  nativeBuildInputs = [
+    qt6.qmake
+    qt6.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    qt6.qtbase
+    qt6.qttools
+    qt6.qtwayland
+  ];
+
+  qmakeFlags = [
+    "./example/qhexedit.pro"
+  ];
+
+  # A custom installPhase is needed because no [native] build input provides an installPhase hook
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin
+    cp qhexedit $out/bin
+
+    runHook postInstall
+  '';
+
+  passthru = {
+    updateScript = nix-update-script { };
+    # I would use testers.testVersion except for some reason it fails, even with my patches that add a --version flag
+    # TODO: Debug why testVersion reports a non-zero status code in the nix sandbox
+  };
+
+  meta = {
+    description = "Hex Editor for Qt";
+    homepage = "https://github.com/Simsys/qhexedit2";
+    changelog = "https://github.com/Simsys/qhexedit2/releases";
+    mainProgram = "qhexedit";
+    license = lib.licenses.lgpl21Only;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ pandapip1 ];
+  };
+})