Artturin
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
92 lines
1.7 KiB
Nix
92 lines
1.7 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildPythonPackage,
|
|
pythonOlder,
|
|
fetchFromGitHub,
|
|
|
|
# build-system
|
|
numpy,
|
|
pybind11,
|
|
setuptools,
|
|
|
|
# dependencies
|
|
clarabel,
|
|
cvxopt,
|
|
ecos,
|
|
osqp,
|
|
scipy,
|
|
scs,
|
|
|
|
# checks
|
|
pytestCheckHook,
|
|
|
|
useOpenmp ? (!stdenv.hostPlatform.isDarwin),
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "cvxpy";
|
|
version = "1.5.3";
|
|
pyproject = true;
|
|
|
|
disabled = pythonOlder "3.9";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "cvxpy";
|
|
repo = "cvxpy";
|
|
rev = "refs/tags/v${version}";
|
|
hash = "sha256-6RaEyFckvF3WhbfeffysMB/zt+aU1NU6B7Nm06znt9k=";
|
|
};
|
|
|
|
# we need to patch out numpy version caps from upstream
|
|
postPatch = ''
|
|
substituteInPlace pyproject.toml \
|
|
--replace-fail "numpy >= 2.0.0" "numpy"
|
|
'';
|
|
|
|
build-system = [
|
|
numpy
|
|
pybind11
|
|
setuptools
|
|
];
|
|
|
|
dependencies = [
|
|
clarabel
|
|
cvxopt
|
|
ecos
|
|
numpy
|
|
osqp
|
|
scipy
|
|
scs
|
|
];
|
|
|
|
nativeCheckInputs = [ pytestCheckHook ];
|
|
|
|
# Required flags from https://github.com/cvxpy/cvxpy/releases/tag/v1.1.11
|
|
preBuild = lib.optionalString useOpenmp ''
|
|
export CFLAGS="-fopenmp"
|
|
export LDFLAGS="-lgomp"
|
|
'';
|
|
|
|
pytestFlagsArray = [ "cvxpy" ];
|
|
|
|
disabledTests = [
|
|
# Disable the slowest benchmarking tests, cuts test time in half
|
|
"test_tv_inpainting"
|
|
"test_diffcp_sdp_example"
|
|
"test_huber"
|
|
"test_partial_problem"
|
|
];
|
|
|
|
pythonImportsCheck = [ "cvxpy" ];
|
|
|
|
meta = {
|
|
description = "Domain-specific language for modeling convex optimization problems in Python";
|
|
homepage = "https://www.cvxpy.org/";
|
|
downloadPage = "https://github.com/cvxpy/cvxpy//releases";
|
|
changelog = "https://github.com/cvxpy/cvxpy/releases/tag/v${version}";
|
|
license = lib.licenses.asl20;
|
|
maintainers = with lib.maintainers; [ drewrisinger ];
|
|
};
|
|
}
|