e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
77 lines
1.7 KiB
Nix
77 lines
1.7 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildPythonPackage,
|
|
autoPatchelfHook,
|
|
onnxruntime,
|
|
coloredlogs,
|
|
numpy,
|
|
packaging,
|
|
oneDNN,
|
|
re2,
|
|
|
|
}:
|
|
|
|
# onnxruntime requires an older protobuf.
|
|
# Doing an override in protobuf in the python-packages set
|
|
# can give you a functioning Python package but note not
|
|
# all Python packages will be compatible then.
|
|
#
|
|
# Because protobuf is not always needed we remove it
|
|
# as a runtime dependency from our wheel.
|
|
#
|
|
# We do include here the non-Python protobuf so the shared libs
|
|
# link correctly. If you do also want to include the Python
|
|
# protobuf, you can add it to your Python env, but be aware
|
|
# the version likely mismatches with what is used here.
|
|
|
|
buildPythonPackage {
|
|
inherit (onnxruntime) pname version;
|
|
format = "wheel";
|
|
src = onnxruntime.dist;
|
|
|
|
unpackPhase = ''
|
|
cp -r $src dist
|
|
chmod +w dist
|
|
'';
|
|
|
|
nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [ autoPatchelfHook ];
|
|
|
|
# This project requires fairly large dependencies such as sympy which we really don't always need.
|
|
pythonRemoveDeps = [
|
|
"flatbuffers"
|
|
"protobuf"
|
|
"sympy"
|
|
];
|
|
|
|
# Libraries are not linked correctly.
|
|
buildInputs =
|
|
[
|
|
oneDNN
|
|
re2
|
|
onnxruntime.protobuf
|
|
]
|
|
++ lib.optionals onnxruntime.passthru.cudaSupport (
|
|
with onnxruntime.passthru.cudaPackages;
|
|
[
|
|
libcublas # libcublasLt.so.XX libcublas.so.XX
|
|
libcurand # libcurand.so.XX
|
|
libcufft # libcufft.so.XX
|
|
cudnn # libcudnn.soXX
|
|
cuda_cudart # libcudart.so.XX
|
|
nccl # libnccl.so.XX
|
|
]
|
|
);
|
|
|
|
propagatedBuildInputs = [
|
|
coloredlogs
|
|
# flatbuffers
|
|
numpy
|
|
packaging
|
|
# protobuf
|
|
# sympy
|
|
];
|
|
|
|
meta = onnxruntime.meta;
|
|
}
|