Ihar Hrachyshka
567e8dfd8e
This commit was created by a combination of scripts and tools: - an ast-grep script to prefix things in meta with `lib.`, - a modified nixf-diagnose / nixf combination to remove unused `with lib;`, and - regular nixfmt. Co-authored-by: Wolfgang Walther <walther@technowledgy.de>
148 lines
4.2 KiB
Nix
148 lines
4.2 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
fetchFromGitHub,
|
|
rocmUpdateScript,
|
|
cmake,
|
|
rocm-cmake,
|
|
rocsparse,
|
|
clr,
|
|
gfortran,
|
|
gtest,
|
|
openmp,
|
|
buildTests ? false,
|
|
buildBenchmarks ? false,
|
|
buildSamples ? false,
|
|
gpuTargets ? [ ],
|
|
}:
|
|
|
|
# This can also use cuSPARSE as a backend instead of rocSPARSE
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "hipsparse";
|
|
version = "6.4.3";
|
|
|
|
outputs = [
|
|
"out"
|
|
]
|
|
++ lib.optionals buildTests [
|
|
"test"
|
|
]
|
|
++ lib.optionals buildSamples [
|
|
"sample"
|
|
];
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ROCm";
|
|
repo = "hipSPARSE";
|
|
rev = "rocm-${finalAttrs.version}";
|
|
hash = "sha256-fbh9fKlzxuIBTeCV/bEQbUS3lO6O3KoGF7/tTqRaCpE=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
rocm-cmake
|
|
clr
|
|
gfortran
|
|
];
|
|
|
|
buildInputs = [
|
|
rocsparse
|
|
]
|
|
++ lib.optionals (buildTests || buildBenchmarks) [
|
|
gtest
|
|
]
|
|
++ lib.optionals (buildTests || buildSamples) [
|
|
openmp
|
|
];
|
|
|
|
cmakeFlags = [
|
|
# Manually define CMAKE_INSTALL_<DIR>
|
|
# See: https://github.com/NixOS/nixpkgs/pull/197838
|
|
"-DCMAKE_INSTALL_BINDIR=bin"
|
|
"-DCMAKE_INSTALL_LIBDIR=lib"
|
|
"-DCMAKE_INSTALL_INCLUDEDIR=include"
|
|
(lib.cmakeBool "BUILD_CLIENTS_TESTS" buildTests)
|
|
(lib.cmakeBool "BUILD_CLIENTS_BENCHMARKS" buildBenchmarks)
|
|
(lib.cmakeBool "BUILD_CLIENTS_SAMPLES" buildSamples)
|
|
]
|
|
++ lib.optionals (gpuTargets != [ ]) [
|
|
"-DAMDGPU_TARGETS=${lib.concatStringsSep ";" gpuTargets}"
|
|
];
|
|
|
|
# We have to manually generate the matrices
|
|
# CMAKE_MATRICES_DIR seems to be reset in clients/tests/CMakeLists.txt
|
|
postPatch = lib.optionalString buildTests ''
|
|
mkdir -p matrices
|
|
|
|
ln -s ${rocsparse.passthru.matrices.matrix-01}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-02}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-03}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-04}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-05}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-06}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-07}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-08}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-09}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-10}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-11}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-12}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-13}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-14}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-15}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-16}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-17}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-18}/*.mtx matrices
|
|
ln -s ${rocsparse.passthru.matrices.matrix-19}/*.mtx matrices
|
|
|
|
# Not used by the original cmake, causes an error
|
|
rm matrices/*_b.mtx
|
|
|
|
echo "deps/convert.cpp -> deps/mtx2csr"
|
|
hipcc deps/convert.cpp -O3 -o deps/mtx2csr
|
|
|
|
for mat in $(ls -1 matrices | cut -d "." -f 1); do
|
|
echo "mtx2csr: $mat.mtx -> $mat.bin"
|
|
deps/mtx2csr matrices/$mat.mtx matrices/$mat.bin
|
|
unlink matrices/$mat.mtx
|
|
done
|
|
|
|
substituteInPlace clients/tests/CMakeLists.txt \
|
|
--replace "\''${PROJECT_BINARY_DIR}/matrices" "/build/source/matrices"
|
|
'';
|
|
|
|
postInstall =
|
|
lib.optionalString buildTests ''
|
|
mkdir -p $test/bin
|
|
mv $out/bin/hipsparse-test $test/bin
|
|
mv /build/source/matrices $test
|
|
rmdir $out/bin
|
|
''
|
|
+ lib.optionalString buildSamples ''
|
|
mkdir -p $sample/bin
|
|
mv clients/staging/example_* $sample/bin
|
|
patchelf --set-rpath $out/lib:${
|
|
lib.makeLibraryPath (
|
|
finalAttrs.buildInputs
|
|
++ [
|
|
clr
|
|
gfortran.cc
|
|
]
|
|
)
|
|
} $sample/bin/example_*
|
|
'';
|
|
|
|
passthru.updateScript = rocmUpdateScript {
|
|
name = finalAttrs.pname;
|
|
inherit (finalAttrs.src) owner;
|
|
inherit (finalAttrs.src) repo;
|
|
};
|
|
|
|
meta = {
|
|
description = "ROCm SPARSE marshalling library";
|
|
homepage = "https://github.com/ROCm/hipSPARSE";
|
|
license = with lib.licenses; [ mit ];
|
|
teams = [ lib.teams.rocm ];
|
|
platforms = lib.platforms.linux;
|
|
};
|
|
})
|