33a5eb7be1
clang-ocl: 5.3.3 → 5.4.0 hip: 5.3.3 → 5.4.0 hipsparse: 5.3.3 → 5.4.0 miopengemm: 5.3.3 → 5.4.0 hipcub: 5.3.3 → 5.4.0 rccl: 5.3.3 → 5.4.0 rocblas: 5.3.3 → 5.4.0 rocfft: 5.3.3 → 5.4.0 miopen: 5.3.3 → 5.4.0 rocm-comgr: 5.3.3 → 5.4.0 rocclr: 5.3.3 → 5.4.0 rocm-device-libs: 5.3.3 → 5.4.0 rocm-cmake: 5.3.3 → 5.4.0 rocm-runtime: 5.3.3 → 5.4.0 rocm-smi: 5.3.3 → 5.4.0 rocm-thunk: 5.3.3 → 5.4.0 rocm-opencl-runtime: 5.3.3 → 5.4.0 llvmPackages_rocm.llvm: 5.3.3 → 5.4.0 rocminfo: 5.3.3 → 5.4.0 rocmlir: 5.3.3 → 5.4.0 rocprim: 5.3.3 → 5.4.0 rocwmma: 5.3.3 → 5.4.0 rocrand: 5.3.3 → 5.4.0 rocsparse: 5.3.3 → 5.4.0 rocthrust: 5.3.3 → 5.4.0 tensile: 5.3.3 → 5.4.0 rocm-llvm: remove obsolete patch hip: remove obsolete substituteInPlace rocmlir: fixup build inputs and cmakeFlags miopen: add nlohmann_json
63 lines
1.9 KiB
Nix
63 lines
1.9 KiB
Nix
{ lib, stdenv
|
|
, fetchFromGitHub
|
|
, fetchpatch
|
|
, writeScript
|
|
, rocm-comgr
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "rocclr";
|
|
version = "5.4.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ROCm-Developer-Tools";
|
|
repo = "ROCclr";
|
|
rev = "rocm-${finalAttrs.version}";
|
|
hash = "sha256-tYFoGafOsJYnRQaOLAaFix6tPD0QPTidOtOicPxP2Vk=";
|
|
};
|
|
|
|
patches = [
|
|
# Enable support for gfx8 again
|
|
# See the upstream issue: https://github.com/RadeonOpenCompute/ROCm/issues/1659
|
|
# And the arch patch: https://github.com/rocm-arch/rocm-arch/pull/742
|
|
(fetchpatch {
|
|
url = "https://raw.githubusercontent.com/John-Gee/rocm-arch/d6812d308fee3caf2b6bb01b4d19fe03a6a0e3bd/rocm-opencl-runtime/enable-gfx800.patch";
|
|
hash = "sha256-59jFDIIsTTZcNns9RyMVWPRUggn/bSlAGrky4quu8B4=";
|
|
})
|
|
];
|
|
|
|
prePatch = ''
|
|
substituteInPlace device/comgrctx.cpp \
|
|
--replace "libamd_comgr.so" "${rocm-comgr}/lib/libamd_comgr.so"
|
|
'';
|
|
|
|
buildPhase = "";
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out
|
|
cp -r * $out/
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
passthru.updateScript = writeScript "update.sh" ''
|
|
#!/usr/bin/env nix-shell
|
|
#!nix-shell -i bash -p curl jq common-updater-scripts
|
|
version="$(curl ''${GITHUB_TOKEN:+"-u \":$GITHUB_TOKEN\""} -sL "https://api.github.com/repos/ROCm-Developer-Tools/ROCclr/tags" | jq '.[].name | split("-") | .[1] | select( . != null )' --raw-output | sort -n | tail -1)"
|
|
update-source-version rocclr "$version" --ignore-same-hash
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Source package of the Radeon Open Compute common language runtime";
|
|
homepage = "https://github.com/ROCm-Developer-Tools/ROCclr";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ lovesegfault ] ++ teams.rocm.members;
|
|
# rocclr seems to have some AArch64 ifdefs, but does not seem
|
|
# to be supported yet by the build infrastructure. Recheck in
|
|
# the future.
|
|
platforms = [ "x86_64-linux" ];
|
|
};
|
|
})
|