5dfdb09561
While preparing this change, I read the git blame on all of the files I touched. I saw a working lifetime of building this system which we use every day and love dearly and keep maintained ourselves. I saw commits from a 14 year range between 2003 to 2017!! I could not be more thankful for Eelco's work on building large parts of the foundation of nixpkgs that all of us rely on now. However, the end date of that range of the files I looked at the blame on was 2017. I did not see surviving code from any newer date than that. Looking at the Git logs, Eelco has been working on other things, and that's totally fine. However, it means that our maintenance metadata is out of date on a lot of packages, and *that*'s the reason I am submitting this change. There are a lot of packages that don't have anyone with their name on them to be pinged if they need attention, even if they have had recent activity (although it is never clear if recent activity was just someone fixing it because ZHF or because the package actually matters to them). There are a lot of packages with storied history that maybe don't need to be in the set anymore at all since they have not been touched in years; or maybe they are simply finished. Empty maintainer lists should be a sign that we need to figure out who maintains it or potentially remove it if it has rotted, and allowing the maintainer list to be empty if it is already not maintained is part of a healthy repository ecology. Either way, I would like to have the maintenance metadata not mislead anyone into sending Eelco emails about packages he doesn't, in practice, work on anymore. I have not removed his name from everything; there are some things that he is the upstream for or has worked on more recently, for instance, like Nix, which I have left alone.
125 lines
3.5 KiB
Nix
125 lines
3.5 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchurl
|
|
, pkg-config
|
|
, glib
|
|
, freetype
|
|
, libintl
|
|
, meson
|
|
, ninja
|
|
, gobject-introspection
|
|
, buildPackages
|
|
, withIntrospection ? lib.meta.availableOn stdenv.hostPlatform gobject-introspection && stdenv.hostPlatform.emulatorAvailable buildPackages
|
|
, icu
|
|
, graphite2
|
|
, harfbuzz # The icu variant uses and propagates the non-icu one.
|
|
, ApplicationServices
|
|
, CoreText
|
|
, withCoreText ? false
|
|
, withIcu ? false # recommended by upstream as default, but most don't needed and it's big
|
|
, withGraphite2 ? true # it is small and major distros do include it
|
|
, python3
|
|
, gtk-doc
|
|
, docbook-xsl-nons
|
|
, docbook_xml_dtd_43
|
|
# for passthru.tests
|
|
, gimp
|
|
, gtk3
|
|
, gtk4
|
|
, mapnik
|
|
, qt5
|
|
, testers
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "harfbuzz${lib.optionalString withIcu "-icu"}";
|
|
version = "9.0.0";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/harfbuzz/harfbuzz/releases/download/${finalAttrs.version}/harfbuzz-${finalAttrs.version}.tar.xz";
|
|
hash = "sha256-pBsnLO65IMVyY+yFFgRULZ7IXuMDBQbZRmIGfHtquJ4=";
|
|
};
|
|
|
|
postPatch = ''
|
|
patchShebangs src/*.py test
|
|
'' + lib.optionalString stdenv.isDarwin ''
|
|
# ApplicationServices.framework headers have cast-align warnings.
|
|
substituteInPlace src/hb.hh \
|
|
--replace '#pragma GCC diagnostic error "-Wcast-align"' ""
|
|
'';
|
|
|
|
outputs = [ "out" "dev" "devdoc" ];
|
|
outputBin = "dev";
|
|
|
|
mesonFlags = [
|
|
# upstream recommends cairo, but it is only used for development purposes
|
|
# and is not part of the library.
|
|
# Cairo causes transitive (build) dependencies on various X11 or other
|
|
# GUI-related libraries, so it shouldn't be re-added lightly.
|
|
(lib.mesonEnable "cairo" false)
|
|
# chafa is only used in a development utility, not in the library
|
|
(lib.mesonEnable "chafa" false)
|
|
(lib.mesonEnable "coretext" withCoreText)
|
|
(lib.mesonEnable "graphite" withGraphite2)
|
|
(lib.mesonEnable "icu" withIcu)
|
|
(lib.mesonEnable "introspection" withIntrospection)
|
|
(lib.mesonOption "cmakepackagedir" "${placeholder "dev"}/lib/cmake")
|
|
];
|
|
|
|
depsBuildBuild = [
|
|
pkg-config
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
libintl
|
|
pkg-config
|
|
python3
|
|
glib
|
|
gtk-doc
|
|
docbook-xsl-nons
|
|
docbook_xml_dtd_43
|
|
] ++ lib.optional withIntrospection gobject-introspection;
|
|
|
|
buildInputs = [ glib freetype ]
|
|
++ lib.optionals withCoreText [ ApplicationServices CoreText ];
|
|
|
|
propagatedBuildInputs = lib.optional withGraphite2 graphite2
|
|
++ lib.optionals withIcu [ icu harfbuzz ];
|
|
|
|
doCheck = true;
|
|
|
|
# Slightly hacky; some pkgs expect them in a single directory.
|
|
postFixup = lib.optionalString withIcu ''
|
|
rm "$out"/lib/libharfbuzz.* "$dev/lib/pkgconfig/harfbuzz.pc"
|
|
ln -s {'${harfbuzz.dev}',"$dev"}/lib/pkgconfig/harfbuzz.pc
|
|
${lib.optionalString stdenv.isDarwin ''
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.dylib
|
|
ln -s {'${harfbuzz.out}',"$out"}/lib/libharfbuzz.0.dylib
|
|
''}
|
|
'';
|
|
|
|
passthru.tests = {
|
|
inherit gimp gtk3 gtk4 mapnik;
|
|
inherit (qt5) qtbase;
|
|
pkg-config = testers.hasPkgConfigModules {
|
|
package = finalAttrs.finalPackage;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "OpenType text shaping engine";
|
|
homepage = "https://harfbuzz.github.io/";
|
|
changelog = "https://github.com/harfbuzz/harfbuzz/raw/${finalAttrs.version}/NEWS";
|
|
maintainers = [ ];
|
|
license = licenses.mit;
|
|
platforms = platforms.unix ++ platforms.windows;
|
|
pkgConfigModules = [
|
|
"harfbuzz"
|
|
"harfbuzz-gobject"
|
|
"harfbuzz-subset"
|
|
];
|
|
};
|
|
})
|