Artturin
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
88 lines
2.0 KiB
Nix
88 lines
2.0 KiB
Nix
{
|
|
stdenv,
|
|
lib,
|
|
buildPythonPackage,
|
|
fetchFromGitHub,
|
|
cargo,
|
|
rustPlatform,
|
|
rustc,
|
|
libiconv,
|
|
typing-extensions,
|
|
pytestCheckHook,
|
|
hypothesis,
|
|
pytest-timeout,
|
|
pytest-mock,
|
|
dirty-equals,
|
|
}:
|
|
|
|
let
|
|
pydantic-core = buildPythonPackage rec {
|
|
pname = "pydantic-core";
|
|
version = "2.20.1";
|
|
pyproject = true;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "pydantic";
|
|
repo = "pydantic-core";
|
|
rev = "refs/tags/v${version}";
|
|
hash = "sha256-iFyCFkFzvTL6es3L96pyq/s6SS7h1mn+bS0SPcsxXxA=";
|
|
};
|
|
|
|
patches = [ ./01-remove-benchmark-flags.patch ];
|
|
|
|
cargoDeps = rustPlatform.fetchCargoTarball {
|
|
inherit src;
|
|
name = "${pname}-${version}";
|
|
hash = "sha256-4v4g9/8ZsQUqkwA29/S/BXn2Ea4eSOnMhEbhDvsGuQU=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
cargo
|
|
rustPlatform.cargoSetupHook
|
|
rustc
|
|
];
|
|
|
|
build-system = [
|
|
rustPlatform.maturinBuildHook
|
|
typing-extensions
|
|
];
|
|
|
|
buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [ libiconv ];
|
|
|
|
dependencies = [ typing-extensions ];
|
|
|
|
pythonImportsCheck = [ "pydantic_core" ];
|
|
|
|
# escape infinite recursion with pydantic via dirty-equals
|
|
doCheck = false;
|
|
passthru.tests.pytest = pydantic-core.overrideAttrs { doCheck = true; };
|
|
|
|
nativeCheckInputs = [
|
|
pytestCheckHook
|
|
hypothesis
|
|
pytest-timeout
|
|
dirty-equals
|
|
pytest-mock
|
|
];
|
|
|
|
disabledTests = [
|
|
# RecursionError: maximum recursion depth exceeded while calling a Python object
|
|
"test_recursive"
|
|
];
|
|
|
|
disabledTestPaths = [
|
|
# no point in benchmarking in nixpkgs build farm
|
|
"tests/benchmarks"
|
|
];
|
|
|
|
meta = with lib; {
|
|
changelog = "https://github.com/pydantic/pydantic-core/releases/tag/v${version}";
|
|
description = "Core validation logic for pydantic written in rust";
|
|
homepage = "https://github.com/pydantic/pydantic-core";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ blaggacao ];
|
|
};
|
|
};
|
|
in
|
|
pydantic-core
|