Artturin
e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
76 lines
1.5 KiB
Nix
76 lines
1.5 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
buildPythonPackage,
|
|
pythonOlder,
|
|
fetchFromGitHub,
|
|
substituteAll,
|
|
graphviz-nox,
|
|
xdg-utils,
|
|
makeFontsConf,
|
|
freefont_ttf,
|
|
setuptools,
|
|
mock,
|
|
pytest_7,
|
|
pytest-mock,
|
|
python,
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "graphviz";
|
|
version = "0.20.3";
|
|
pyproject = true;
|
|
|
|
disabled = pythonOlder "3.8";
|
|
|
|
# patch does not apply to PyPI tarball due to different line endings
|
|
src = fetchFromGitHub {
|
|
owner = "xflr6";
|
|
repo = "graphviz";
|
|
rev = "refs/tags/${version}";
|
|
hash = "sha256-IqjqcBEL4BK/VfRjdxJ9t/DkG8OMAoXJxbW5JXpALuw=";
|
|
};
|
|
|
|
patches = [
|
|
(substituteAll {
|
|
src = ./paths.patch;
|
|
graphviz = graphviz-nox;
|
|
xdgutils = xdg-utils;
|
|
})
|
|
];
|
|
|
|
postPatch = ''
|
|
sed -i "/--cov/d" setup.cfg
|
|
'';
|
|
|
|
# Fontconfig error: Cannot load default config file
|
|
FONTCONFIG_FILE = makeFontsConf { fontDirectories = [ freefont_ttf ]; };
|
|
|
|
build-system = [ setuptools ];
|
|
|
|
nativeCheckInputs = [
|
|
mock
|
|
pytest_7
|
|
pytest-mock
|
|
];
|
|
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
HOME=$TMPDIR ${python.interpreter} run-tests.py
|
|
|
|
runHook postCheck
|
|
'';
|
|
|
|
# Too many failures due to attempting to connect to com.apple.fonts daemon
|
|
doCheck = !stdenv.hostPlatform.isDarwin;
|
|
|
|
meta = with lib; {
|
|
description = "Simple Python interface for Graphviz";
|
|
homepage = "https://github.com/xflr6/graphviz";
|
|
changelog = "https://github.com/xflr6/graphviz/blob/${src.rev}/CHANGES.rst";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ dotlambda ];
|
|
};
|
|
}
|