Silvan Mosberger
4f0dadbf38
After final improvements to the official formatter implementation,
this commit now performs the first treewide reformat of Nix files using it.
This is part of the implementation of RFC 166.
Only "inactive" files are reformatted, meaning only files that
aren't being touched by any PR with activity in the past 2 months.
This is to avoid conflicts for PRs that might soon be merged.
Later we can do a full treewide reformat to get the rest,
which should not cause as many conflicts.
A CI check has already been running for some time to ensure that new and
already-formatted files are formatted, so the files being reformatted here
should also stay formatted.
This commit was automatically created and can be verified using
nix-build https://github.com/infinisil/treewide-nixpkgs-reformat-script/archive/a08b3a4d199c6124ac5b36a889d9099b4383463f.tar.gz \
--argstr baseRev b32a094368
result/bin/apply-formatting $NIXPKGS_PATH
49 lines
1.1 KiB
Nix
49 lines
1.1 KiB
Nix
/*
|
|
A set of aliases to be used in generated expressions.
|
|
|
|
In case of ambiguity, this will pick a sensible default.
|
|
|
|
This was initially based on cabal2nix's mapping.
|
|
|
|
It'd be nice to generate this mapping, based on a set of derivations.
|
|
It can not be fully automated, so it should be a expression or tool
|
|
that makes suggestions about which pkg-config module names can be added.
|
|
*/
|
|
pkgs:
|
|
|
|
let
|
|
inherit (pkgs) lib;
|
|
inherit (lib)
|
|
all
|
|
flip
|
|
mapAttrs
|
|
mapAttrsToList
|
|
getAttrFromPath
|
|
importJSON
|
|
;
|
|
|
|
data = importJSON ./pkg-config-data.json;
|
|
inherit (data) modules;
|
|
|
|
platform = pkgs.stdenv.hostPlatform;
|
|
|
|
isSupported =
|
|
moduleData:
|
|
moduleData ? supportedWhenPlatformAttrsEqual
|
|
-> all (x: x) (
|
|
mapAttrsToList (
|
|
k: v: platform ? ${k} && platform.${k} == v
|
|
) moduleData.supportedWhenPlatformAttrsEqual
|
|
);
|
|
|
|
modulePkgs = flip mapAttrs modules (
|
|
_moduleName: moduleData:
|
|
if moduleData ? attrPath && isSupported moduleData then
|
|
getAttrFromPath moduleData.attrPath pkgs
|
|
else
|
|
null
|
|
);
|
|
|
|
in
|
|
modulePkgs
|