Sergei Trofimovich
aeddad8ac1
These are emabled upstream by default, a part of ZIP spec: https://en.wikipedia.org/wiki/ZIP_(file_format)#Compression_methods And don't increase closure size much in practice: https://github.com/NixOS/nixpkgs/issues/496396#issuecomment-3995616523 Closes: https://github.com/NixOS/nixpkgs/issues/496396
67 lines
1.4 KiB
Nix
67 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
stdenv,
|
|
cmake,
|
|
fetchurl,
|
|
perl,
|
|
zlib,
|
|
groff,
|
|
withBzip2 ? true,
|
|
bzip2,
|
|
withLZMA ? true,
|
|
xz,
|
|
withOpenssl ? false,
|
|
openssl,
|
|
withZstd ? true,
|
|
zstd,
|
|
testers,
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "libzip";
|
|
version = "1.11.4";
|
|
|
|
src = fetchurl {
|
|
url = "https://libzip.org/download/libzip-${finalAttrs.version}.tar.gz";
|
|
hash = "sha256-guny8kIfnXwkZrvDFzzQlZWojqN9sNVZqdCi3GDcci4=";
|
|
};
|
|
|
|
outputs = [
|
|
"out"
|
|
"dev"
|
|
"man"
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
perl
|
|
groff
|
|
];
|
|
propagatedBuildInputs = [ zlib ];
|
|
buildInputs =
|
|
lib.optionals withLZMA [ xz ]
|
|
++ lib.optionals withBzip2 [ bzip2 ]
|
|
++ lib.optionals withOpenssl [ openssl ]
|
|
++ lib.optionals withZstd [ zstd ];
|
|
|
|
# Don't build the regression tests because they don't build with
|
|
# pkgsStatic and are not executed anyway.
|
|
cmakeFlags = [ "-DBUILD_REGRESS=0" ];
|
|
|
|
preCheck = ''
|
|
# regress/runtest is a generated file
|
|
patchShebangs regress
|
|
'';
|
|
|
|
passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
|
|
|
|
meta = {
|
|
homepage = "https://libzip.org/";
|
|
description = "C library for reading, creating and modifying zip archives";
|
|
license = lib.licenses.bsd3;
|
|
pkgConfigModules = [ "libzip" ];
|
|
platforms = lib.platforms.unix;
|
|
changelog = "https://github.com/nih-at/libzip/blob/v${finalAttrs.version}/NEWS.md";
|
|
};
|
|
})
|