374e6bcc40
Format all Nix files using the officially approved formatter,
making the CI check introduced in the previous commit succeed:
nix-build ci -A fmt.check
This is the next step of the of the [implementation](https://github.com/NixOS/nixfmt/issues/153)
of the accepted [RFC 166](https://github.com/NixOS/rfcs/pull/166).
This commit will lead to merge conflicts for a number of PRs,
up to an estimated ~1100 (~33%) among the PRs with activity in the past 2
months, but that should be lower than what it would be without the previous
[partial treewide format](https://github.com/NixOS/nixpkgs/pull/322537).
Merge conflicts caused by this commit can now automatically be resolved while rebasing using the
[auto-rebase script](8616af08d9/maintainers/scripts/auto-rebase).
If you run into any problems regarding any of this, please reach out to the
[formatting team](https://nixos.org/community/teams/formatting/) by
pinging @NixOS/nix-formatting.
84 lines
2.0 KiB
Nix
84 lines
2.0 KiB
Nix
{
|
|
stdenv,
|
|
lib,
|
|
lightdm-gtk-greeter,
|
|
fetchurl,
|
|
lightdm,
|
|
pkg-config,
|
|
intltool,
|
|
linkFarm,
|
|
wrapGAppsHook3,
|
|
gtk3,
|
|
xfce4-dev-tools,
|
|
at-spi2-core,
|
|
librsvg,
|
|
hicolor-icon-theme,
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "lightdm-gtk-greeter";
|
|
version = "2.0.9";
|
|
|
|
src = fetchurl {
|
|
# Release tarball differs from source tarball.
|
|
url = "https://github.com/Xubuntu/lightdm-gtk-greeter/releases/download/lightdm-gtk-greeter-${version}/lightdm-gtk-greeter-${version}.tar.gz";
|
|
hash = "sha256-yP3xmKqaP50NrQtI3+I8Ine3kQfo/PxillKQ8QgfZF0=";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
intltool
|
|
xfce4-dev-tools
|
|
wrapGAppsHook3
|
|
];
|
|
|
|
buildInputs = [
|
|
lightdm
|
|
librsvg
|
|
hicolor-icon-theme
|
|
gtk3
|
|
];
|
|
|
|
configureFlags = [
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--disable-indicator-services-command"
|
|
"--sbindir=${placeholder "out"}/bin" # for wrapGAppsHook3 to wrap automatically
|
|
];
|
|
|
|
postPatch = ''
|
|
# https://github.com/Xubuntu/lightdm-gtk-greeter/pull/178
|
|
cp data/badges/xfce{,-wayland}_badge-symbolic.svg
|
|
'';
|
|
|
|
preConfigure = ''
|
|
configureFlagsArray+=( --enable-at-spi-command="${at-spi2-core}/libexec/at-spi-bus-launcher --launch-immediately" )
|
|
'';
|
|
|
|
installFlags = [
|
|
"localstatedir=\${TMPDIR}"
|
|
"sysconfdir=${placeholder "out"}/etc"
|
|
];
|
|
|
|
postInstall = ''
|
|
substituteInPlace "$out/share/xgreeters/lightdm-gtk-greeter.desktop" \
|
|
--replace-fail "Exec=lightdm-gtk-greeter" "Exec=$out/bin/lightdm-gtk-greeter"
|
|
'';
|
|
|
|
passthru.xgreeters = linkFarm "lightdm-gtk-greeter-xgreeters" [
|
|
{
|
|
path = "${lightdm-gtk-greeter}/share/xgreeters/lightdm-gtk-greeter.desktop";
|
|
name = "lightdm-gtk-greeter.desktop";
|
|
}
|
|
];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/Xubuntu/lightdm-gtk-greeter";
|
|
description = "GTK greeter for LightDM";
|
|
mainProgram = "lightdm-gtk-greeter";
|
|
platforms = platforms.linux;
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ bobby285271 ];
|
|
};
|
|
}
|