From fdbbfb693a0b4c3f17fb41d51b5802894c9c6928 Mon Sep 17 00:00:00 2001
From: Fabian Affolter <mail@fabian-affolter.ch>
Date: Sun, 5 Jul 2026 10:57:51 +0200
Subject: [PATCH] whale: init at 0.1.62

Terminal-first AI coding agent for DeepSeek

https://github.com/usewhale/Whale
---
 pkgs/by-name/wh/whale/package.nix | 57 +++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pkgs/by-name/wh/whale/package.nix

diff --git a/pkgs/by-name/wh/whale/package.nix b/pkgs/by-name/wh/whale/package.nix
new file mode 100644
index 000000000000..71090fabc427
--- /dev/null
+++ b/pkgs/by-name/wh/whale/package.nix
@@ -0,0 +1,57 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  gitMinimal,
+  nix-update-script,
+  versionCheckHook,
+  writableTmpDirAsHomeHook,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "whale";
+  version = "0.1.62";
+
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "usewhale";
+    repo = "Whale";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-EvuNdgpW5M+i33tGLurQDq0z+Ht/z5agIsaWWapXqpY=";
+  };
+
+  vendorHash = "sha256-YBY5b2SLcWeiCQDZELJdsi+mJ+YEuo+yTbotUlLgqEA=";
+
+  nativeCheckInputs = [
+    gitMinimal
+    writableTmpDirAsHomeHook
+  ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  ldflags = [
+    "-s"
+    "-X=github.com/usewhale/whale/internal/build.Version=${finalAttrs.version}"
+  ];
+
+  excludedPackages = [ "cmd/dev" ];
+
+  checkFlags = [
+    # Fails in the sandbox
+    "-skip=TestRulePolicyMCPPathOutsideWorkspaceRequiresExternalDirectoryApproval"
+  ];
+
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Terminal-first AI coding agent for DeepSeek";
+    homepage = "https://github.com/usewhale/Whale";
+    changelog = "https://github.com/usewhale/Whale/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ fab ];
+    mainProgram = "whale";
+  };
+})