From fd4160770720aa2e2137e738b054c5ebe23cface Mon Sep 17 00:00:00 2001
From: Xinyao Zhang <zhangxy_2023@163.com>
Date: Thu, 27 Nov 2025 22:33:45 +0800
Subject: [PATCH] networkmanager-ssh: init at 1.4.2

Co-authored-by: Acid Bong <acidbong@tilde.club>
---
 .../by-name/ne/networkmanager-ssh/package.nix | 69 +++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 pkgs/by-name/ne/networkmanager-ssh/package.nix

diff --git a/pkgs/by-name/ne/networkmanager-ssh/package.nix b/pkgs/by-name/ne/networkmanager-ssh/package.nix
new file mode 100644
index 000000000000..b889c89d714e
--- /dev/null
+++ b/pkgs/by-name/ne/networkmanager-ssh/package.nix
@@ -0,0 +1,69 @@
+{
+  stdenv,
+  lib,
+  autoreconfHook,
+  fetchFromGitHub,
+  pkg-config,
+  networkmanager,
+  libsecret,
+  gtk3,
+  gtk4,
+  libnma-gtk4,
+  intltool,
+  openssh,
+  sshpass,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "NetworkManager-ssh";
+  version = "1.4.2";
+
+  src = fetchFromGitHub {
+    owner = "danfruehauf";
+    repo = "NetworkManager-ssh";
+    tag = finalAttrs.version;
+    hash = "sha256-ExCU22V4fYuFXW/HqJ39+PbYykXu4rpk8+3/hg9KTMo=";
+  };
+
+  postPatch = ''
+    substituteInPlace src/nm-ssh-service.c \
+      --replace-fail /usr/bin/sshpass ${lib.getExe sshpass} \
+      --replace-fail /usr/bin/ssh ${lib.getExe openssh}
+  '';
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    intltool
+    gtk4
+  ];
+
+  buildInputs = [
+    networkmanager
+    gtk3
+    gtk4
+    libsecret
+    libnma-gtk4
+  ];
+
+  configureFlags = [
+    "--with-gtk4"
+    "--enable-absolute-paths"
+  ];
+
+  strictDeps = true;
+
+  passthru = {
+    networkManagerPlugin = "VPN/nm-ssh-service.name";
+  };
+
+  meta = {
+    description = "SSH VPN integration for NetworkManager";
+    homepage = "https://github.com/danfruehauf/NetworkManager-ssh";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      zhangxy
+    ];
+    inherit (networkmanager.meta) platforms;
+  };
+})