diff --git a/pkgs/development/python-modules/hebi-py/default.nix b/pkgs/development/python-modules/hebi-py/default.nix
new file mode 100644
index 000000000000..1a499724a11a
--- /dev/null
+++ b/pkgs/development/python-modules/hebi-py/default.nix
@@ -0,0 +1,54 @@
+{
+  lib,
+  python,
+  buildPythonPackage,
+  fetchPypi,
+  setuptools,
+  numpy,
+  patchelfUnstable,
+  pyyaml,
+  nix-update-script,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "hebi-py";
+  version = "2.7.9";
+  pyproject = true;
+
+  src = fetchPypi {
+    pname = "hebi-py";
+    inherit (finalAttrs) version;
+    hash = "sha256-7B0oxG1CVDTUVDFTJpuYvaCj+HnCL/2zmsD33W4nTLs=";
+  };
+
+  __structuredAttrs = true;
+  strictDeps = true;
+  build-system = [
+    setuptools
+    patchelfUnstable # Depends on --clear-execstack which is not in any tagged release yet
+  ];
+  dependencies = [
+    numpy
+    pyyaml
+  ];
+
+  doCheck = false; # no tests
+
+  postFixup = ''
+    for lib in $out/${python.sitePackages}/hebi/lib/linux_x86_64/libhebi.so*; do
+      patchelf --clear-execstack "$lib"
+    done
+  '';
+
+  pythonImportsCheck = [ "hebi" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Python library for the Hebi Robotics API";
+    homepage = "https://docs.hebi.us/";
+    license = lib.licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with lib.maintainers; [ pandapip1 ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 30560967024b..3a3f14ad6878 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -7192,6 +7192,8 @@ self: super: with self; {
 
   hebg = callPackage ../development/python-modules/hebg { };
 
+  hebi-py = callPackage ../development/python-modules/hebi-py { };
+
   hegel-ip-client = callPackage ../development/python-modules/hegel-ip-client { };
 
   helion = callPackage ../development/python-modules/helion { };