From 50dc03bd128504e6f2cf0c46a749ed9fa9751cf1 Mon Sep 17 00:00:00 2001
From: Oleksii Filonenko <github@brightone.cloud>
Date: Mon, 6 Jul 2026 17:51:30 +0100
Subject: [PATCH] aver: init at 0.26.0

aver: add versionCheckHook

Co-authored-by: Ross George <mrrosspgeorge@gmail.com>
---
 pkgs/by-name/av/aver/package.nix | 49 ++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 pkgs/by-name/av/aver/package.nix

diff --git a/pkgs/by-name/av/aver/package.nix b/pkgs/by-name/av/aver/package.nix
new file mode 100644
index 000000000000..2174d4d5f268
--- /dev/null
+++ b/pkgs/by-name/av/aver/package.nix
@@ -0,0 +1,49 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  lld,
+  nix-update-script,
+  versionCheckHook,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "aver";
+  version = "0.26.0";
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "jasisz";
+    repo = "aver";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-LeI6qy+z8azrrgoskRq/hsk5t0PDydQ/yJNxYIB7I68=";
+  };
+
+  cargoHash = "sha256-Zqu56tBbKjWZmpRpPuK9JMexcajRcDzBW4AfTRAkPbs=";
+
+  cargoBuildFlags = [
+    "--workspace"
+    "--bin=aver"
+    "--bin=aver-lsp"
+  ];
+
+  nativeBuildInputs = lib.optionals stdenv.hostPlatform.isDarwin [ lld ];
+
+  # some tests are generated, some take a long time, some need to be skipped
+  doCheck = false;
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Programming language for auditable AI-written code";
+    homepage = "https://github.com/jasisz/aver";
+    changelog = "https://github.com/jasisz/aver/blob/${finalAttrs.src.tag}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ Br1ght0ne ];
+    mainProgram = "aver";
+  };
+})