From 2e6b498101477d203b5a5475cf78f3a14dc35828 Mon Sep 17 00:00:00 2001
From: bubblepipe42 <bubblepipe42@gmail.com>
Date: Fri, 3 Oct 2025 16:30:06 +0800
Subject: [PATCH] wamrc: init at 2.3.1

---
 pkgs/by-name/wa/wamrc/package.nix | 50 +++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/wa/wamrc/package.nix

diff --git a/pkgs/by-name/wa/wamrc/package.nix b/pkgs/by-name/wa/wamrc/package.nix
new file mode 100644
index 000000000000..f2143da08c18
--- /dev/null
+++ b/pkgs/by-name/wa/wamrc/package.nix
@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  llvmPackages,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wamrc";
+  version = "2.3.1";
+
+  src = fetchFromGitHub {
+    owner = "bytecodealliance";
+    repo = "wasm-micro-runtime";
+    tag = "WAMR-${finalAttrs.version}";
+    hash = "sha256-Rhn26TRyjkR30+zyosfooOGjhvG+ztYtJVQlRfzWEFo=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    llvmPackages.llvm
+  ];
+
+  cmakeFlags =
+    lib.optionals stdenv.hostPlatform.isDarwin [
+      "-DCMAKE_OSX_DEPLOYMENT_TARGET=${stdenv.hostPlatform.darwinSdkVersion}"
+    ]
+    ++ [
+      "-DWAMR_BUILD_WITH_CUSTOM_LLVM=ON"
+      "-DLLVM_DIR=${llvmPackages.llvm.dev}/lib/cmake/llvm"
+    ];
+
+  sourceRoot = "${finalAttrs.src.name}/wamr-compiler";
+
+  passthru.updateScript = nix-update-script { extraArgs = [ "--version-regex=WAMR-(.*)" ]; };
+
+  meta = {
+    description = "WebAssembly Micro Runtime AOT compiler";
+    homepage = "https://github.com/bytecodealliance/wasm-micro-runtime";
+    license = lib.licenses.asl20;
+    mainProgram = "wamrc";
+    maintainers = with lib.maintainers; [ bubblepipe ];
+    platforms = lib.platforms.unix;
+  };
+})