From f31ae362f3103a80cd4e03a43124125c7a415621 Mon Sep 17 00:00:00 2001
From: xZecora <111700bh@gmail.com>
Date: Tue, 21 Jul 2026 16:59:47 -0400
Subject: [PATCH] turnstile: init at 0.1.11

---
 pkgs/by-name/tu/turnstile/package.nix | 66 +++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 pkgs/by-name/tu/turnstile/package.nix

diff --git a/pkgs/by-name/tu/turnstile/package.nix b/pkgs/by-name/tu/turnstile/package.nix
new file mode 100644
index 000000000000..ff974230800e
--- /dev/null
+++ b/pkgs/by-name/tu/turnstile/package.nix
@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  scdoc,
+  meson,
+  ninja,
+  pam,
+  dinitSupport ? true,
+  dinit,
+  runitSupport ? true,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "turnstile";
+  version = "0.1.11";
+
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "chimera-linux";
+    repo = "turnstile";
+    tag = "v${finalAttrs.version}";
+    sha256 = "sha256-94J+w0RHxzw7wS70LcpEzMvgevAqAwl0EtiANUmdRYU=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    pkg-config
+    scdoc
+    meson
+    ninja
+  ];
+
+  buildInputs = [
+    scdoc
+    pam
+  ];
+
+  postPatch = ''
+    substituteInPlace meson.build \
+      --replace-fail "get_option('prefix'), get_option('sysconfdir'), 'turnstile'" "'/etc', 'turnstile'"
+  ''
+  + lib.optionalString dinitSupport ''
+    substituteInPlace backend/dinit \
+      --replace-fail '/usr/bin/dinit-monitor' '${lib.getExe' dinit "dinit-monitor"}'
+  '';
+
+  mesonFlags = [
+    "-Dlocalstatedir=/var"
+    "-Dpam_moddir=${placeholder "out"}/lib/security"
+    (lib.mesonEnable "dinit" dinitSupport)
+    (lib.mesonEnable "runit" runitSupport)
+  ];
+
+  meta = {
+    homepage = "https://github.com/chimera-linux/turnstile";
+    description = "This program waits for user logins and then runs the associated user-service manager";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ vitrial ];
+    mainProgram = "turnstiled";
+  };
+
+})