From f05962d7fc11a4c9daf232b3b79a5bad53df1879 Mon Sep 17 00:00:00 2001
From: thiloho <123883702+thiloho@users.noreply.github.com>
Date: Sat, 14 Dec 2024 16:34:33 +0100
Subject: [PATCH] archtika: init at 1.0.1

archtika: fix allow-import-from-derivation error for npm

archtika: fix package formatting

archtika: refactor package

archtika: update GitHub hash for version 1.0.1

archtika: add auto update script

archtika: refactor package

archtika: update version to 1.1.0

archtika: update GitHub hash to version 1.1.0

archtika: update version to 1.2.0
---
 pkgs/by-name/ar/archtika/package.nix | 62 ++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 pkgs/by-name/ar/archtika/package.nix

diff --git a/pkgs/by-name/ar/archtika/package.nix b/pkgs/by-name/ar/archtika/package.nix
new file mode 100644
index 000000000000..c59c95e9516e
--- /dev/null
+++ b/pkgs/by-name/ar/archtika/package.nix
@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  buildNpmPackage,
+  importNpmLock,
+  symlinkJoin,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+let
+  version = "1.2.0";
+
+  src = fetchFromGitHub {
+    owner = "archtika";
+    repo = "archtika";
+    tag = "v${version}";
+    hash = "sha256-ba9da7LqCE/e2lhRVHD7GOhwOj1fNTBbN/pARPMzIg4=";
+  };
+
+  web = buildNpmPackage {
+    name = "web-app";
+    src = "${src}/web-app";
+    npmDepsHash = "sha256-RTyo7K/Hr1hBGtcBKynrziUInl91JqZl84NkJg16ufA=";
+    npmFlags = [ "--legacy-peer-deps" ];
+    installPhase = ''
+      mkdir -p $out/web-app
+      cp package.json $out/web-app
+      cp -r node_modules $out/web-app
+      cp -r build/* $out/web-app
+      cp -r template-styles $out/web-app
+    '';
+  };
+
+  api = stdenv.mkDerivation {
+    name = "api";
+    src = "${src}/rest-api";
+    installPhase = ''
+      mkdir -p $out/rest-api/db/migrations
+      cp -r db/migrations/* $out/rest-api/db/migrations
+    '';
+  };
+in
+symlinkJoin {
+  pname = "archtika";
+  inherit version;
+
+  paths = [
+    web
+    api
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Modern, performant and lightweight CMS";
+    homepage = "https://archtika.com";
+    license = lib.licenses.gpl3;
+    maintainers = [ lib.maintainers.thiloho ];
+    platforms = lib.platforms.unix;
+  };
+}