diff --git a/pkgs/by-name/ya/yazi/plugins/default.nix b/pkgs/by-name/ya/yazi/plugins/default.nix
new file mode 100644
index 000000000000..80905a62b24a
--- /dev/null
+++ b/pkgs/by-name/ya/yazi/plugins/default.nix
@@ -0,0 +1,10 @@
+{ lib, callPackage }:
+let
+  root = ./.;
+  call = name: callPackage (root + "/${name}") { };
+in
+lib.pipe root [
+  builtins.readDir
+  (lib.filterAttrs (_: type: type == "directory"))
+  (builtins.mapAttrs (name: _: call name))
+]
diff --git a/pkgs/by-name/ya/yazi/plugins/full-border/default.nix b/pkgs/by-name/ya/yazi/plugins/full-border/default.nix
new file mode 100644
index 000000000000..41aa381a49e6
--- /dev/null
+++ b/pkgs/by-name/ya/yazi/plugins/full-border/default.nix
@@ -0,0 +1,35 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+}:
+stdenvNoCC.mkDerivation {
+  pname = "full-border.yazi";
+  version = "25.2.26-unstable-2025-03-11";
+
+  src = fetchFromGitHub {
+    owner = "yazi-rs";
+    repo = "plugins";
+    rev = "92f78dc6d0a42569fd0e9df8f70670648b8afb78";
+    hash = "sha256-mqo71VLZsHmgTybxgqKNo9F2QeMuCSvZ89uen1VbWb4=";
+  };
+
+  # NOTE: License is a relative symbolic link
+  # We remove the link and copy the true license
+  installPhase = ''
+    runHook preInstall
+
+    cp -r full-border.yazi $out
+    rm $out/LICENSE
+    cp LICENSE $out
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Add a full border to Yazi to make it look fancier";
+    homepage = "https://yazi-rs.github.io";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ khaneliman ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3876c0063928..588586806394 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -19571,6 +19571,8 @@ with pkgs;
 
   duden = python3Packages.toPythonApplication python3Packages.duden;
 
+  yaziPlugins = recurseIntoAttrs (callPackage ../by-name/ya/yazi/plugins { });
+
   yazi-unwrapped = callPackage ../by-name/ya/yazi-unwrapped/package.nix {
     inherit (darwin.apple_sdk.frameworks) Foundation;
   };