From ee979d9ced99bc2d7aae6bde0b07acaf84d4596e Mon Sep 17 00:00:00 2001
From: Yaroslav Bolyukin <iam@lach.pw>
Date: Sun, 8 Mar 2026 21:16:08 +0100
Subject: [PATCH] python3Packages.kaldi-native-fbank: init at 1.22.3

---
 .../kaldi-native-fbank/default.nix            | 46 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 48 insertions(+)
 create mode 100644 pkgs/development/python-modules/kaldi-native-fbank/default.nix

diff --git a/pkgs/development/python-modules/kaldi-native-fbank/default.nix b/pkgs/development/python-modules/kaldi-native-fbank/default.nix
new file mode 100644
index 000000000000..3d1d2d78009a
--- /dev/null
+++ b/pkgs/development/python-modules/kaldi-native-fbank/default.nix
@@ -0,0 +1,46 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  cmake,
+  setuptools,
+  pybind11,
+  kissfft,
+}:
+buildPythonPackage (finalAttrs: {
+  pname = "kaldi-native-fbank";
+  version = "1.22.3";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "csukuangfj";
+    repo = "kaldi-native-fbank";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Wu4wM52T6NoQ1t5/iAyPtkEGnZki5P0jx0eYMFZMb5o=";
+  };
+
+  build-system = [
+    cmake
+    setuptools
+  ];
+
+  buildInputs = [ pybind11 ];
+
+  dontUseCmakeConfigure = true;
+
+  env.KALDI_NATIVE_FBANK_CMAKE_ARGS = lib.concatStringsSep " " [
+    "-DFETCHCONTENT_SOURCE_DIR_KISSFFT=${kissfft.src}"
+    "-DFETCHCONTENT_SOURCE_DIR_PYBIND11=${pybind11.src}"
+    "-DKALDI_NATIVE_FBANK_BUILD_TESTS=OFF"
+    "-DKALDI_NATIVE_FBANK_BUILD_PYTHON=ON"
+  ];
+
+  pythonImportsCheck = [ "kaldi_native_fbank" ];
+
+  meta = {
+    description = "Kaldi-compatible online fbank extractor without external dependencies";
+    homepage = "https://github.com/csukuangfj/kaldi-native-fbank";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ lach ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 71cde6210b1a..cc7d09532fa2 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -8149,6 +8149,8 @@ self: super: with self; {
 
   kaldi-active-grammar = callPackage ../development/python-modules/kaldi-active-grammar { };
 
+  kaldi-native-fbank = callPackage ../development/python-modules/kaldi-native-fbank { };
+
   kaleido = callPackage ../development/python-modules/kaleido { };
 
   kalshi-python = callPackage ../development/python-modules/kalshi-python { };