From 3086bb9365b4c3e803e73872c80a7a6ba6120417 Mon Sep 17 00:00:00 2001
From: Yifei Sun <ysun@hey.com>
Date: Tue, 1 Apr 2025 00:42:27 -0400
Subject: [PATCH] monocle: init at 0.8.0

---
 pkgs/by-name/mo/monocle/package.nix | 46 +++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 pkgs/by-name/mo/monocle/package.nix

diff --git a/pkgs/by-name/mo/monocle/package.nix b/pkgs/by-name/mo/monocle/package.nix
new file mode 100644
index 000000000000..dda720c31345
--- /dev/null
+++ b/pkgs/by-name/mo/monocle/package.nix
@@ -0,0 +1,46 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "monocle";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    owner = "bgpkit";
+    repo = "monocle";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-vpGCYU/vW4cQFuAWxa+ZkuKLB4NSs5tPW2iWVE8iPAk=";
+  };
+
+  useFetchCargoVendor = true;
+  cargoHash = "sha256-1wouA1REbPHm/v4ZB76gfgDPweNV3nztf6XxKdu42GQ=";
+
+  # require internet access
+  checkFlags = [
+    "--skip=datasets::as2org::tests::test_crawling"
+    "--skip=datasets::ip::tests::test_fetch_ip_info"
+    "--skip=datasets::rpki::validator::tests::test_bgp"
+    "--skip=datasets::rpki::validator::tests::test_list_asn"
+    "--skip=datasets::rpki::validator::tests::test_list_prefix"
+    "--skip=datasets::rpki::validator::tests::test_validation"
+  ];
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "See through all BGP data with a monocle";
+    homepage = "https://github.com/bgpkit/monocle";
+    changelog = "https://github.com/bgpkit/monocle/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ stepbrobd ];
+    mainProgram = "monocle";
+  };
+})