From edbce77c45580d1f11eb44d908c0775978bb4fde Mon Sep 17 00:00:00 2001
From: Liam Murphy <liampm32@gmail.com>
Date: Sat, 8 Mar 2025 19:05:03 +1100
Subject: [PATCH] bender: init at 0.28.1

---
 pkgs/by-name/be/bender/package.nix | 43 ++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 pkgs/by-name/be/bender/package.nix

diff --git a/pkgs/by-name/be/bender/package.nix b/pkgs/by-name/be/bender/package.nix
new file mode 100644
index 000000000000..62465ffbe764
--- /dev/null
+++ b/pkgs/by-name/be/bender/package.nix
@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  gitMinimal,
+}:
+let
+  target = stdenv.hostPlatform.rust.cargoShortTarget;
+in
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "bender";
+  version = "0.28.1";
+
+  src = fetchFromGitHub {
+    owner = "pulp-platform";
+    repo = "bender";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-eC4BY3ri73vgEtcXoPQ5NDknjZcPrKOzLo2vXWj4Adg=";
+  };
+
+  useFetchCargoVendor = true;
+  cargoHash = "sha256-fV4pWSRNlXCdnpeDgg3QW8s1Ixd1LEY8qP/Pb4t5xdc=";
+
+  nativeCheckInputs = [ gitMinimal ];
+  postCheck = ''
+    patchShebangs --build tests
+    BENDER="target/${target}/$cargoBuildType/bender" tests/run_all.sh
+  '';
+
+  meta = {
+    description = "Dependency management tool for hardware projects";
+    homepage = "https://github.com/pulp-platform/bender";
+    changelog = "https://github.com/pulp-platform/bender/releases/tag/${finalAttrs.src.rev}";
+    license = with lib.licenses; [
+      asl20
+      mit
+    ];
+    maintainers = with lib.maintainers; [ Liamolucko ];
+    mainProgram = "bender";
+    platforms = lib.platforms.all;
+  };
+})