From ed8c3cb662bcc5a6ac033e44dfacef810d8e53e8 Mon Sep 17 00:00:00 2001
From: "Alexander V. Nikolaev" <avn@avnik.info>
Date: Sun, 16 Mar 2025 18:03:51 +0200
Subject: [PATCH] brewtarget: 3.0.5 -> 4.0.17

* Update to 4.0.17
* Modernize, move to pkgs/by-name
* Add myself as a maintainer

Signed-off-by: Alexander V. Nikolaev <avn@avnik.info>
---
 pkgs/applications/misc/brewtarget/default.nix | 52 ---------------
 pkgs/by-name/br/brewtarget/package.nix        | 66 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 -
 3 files changed, 66 insertions(+), 54 deletions(-)
 delete mode 100644 pkgs/applications/misc/brewtarget/default.nix
 create mode 100644 pkgs/by-name/br/brewtarget/package.nix

diff --git a/pkgs/applications/misc/brewtarget/default.nix b/pkgs/applications/misc/brewtarget/default.nix
deleted file mode 100644
index 72e7df62486a..000000000000
--- a/pkgs/applications/misc/brewtarget/default.nix
+++ /dev/null
@@ -1,52 +0,0 @@
-{
-  lib,
-  mkDerivation,
-  fetchFromGitHub,
-  bash,
-  cmake,
-  boost,
-  xercesc,
-  xalanc,
-  qtbase,
-  qttools,
-  qtmultimedia,
-  qtsvg,
-}:
-
-mkDerivation rec {
-  pname = "brewtarget";
-  version = "3.0.5";
-
-  src = fetchFromGitHub {
-    owner = "Brewtarget";
-    repo = pname;
-    rev = "v${version}";
-    sha256 = "sha256-PqaiZ2eLH8+qRRkIolnQClTL9O9EgHMqFH/nUffosV8=";
-  };
-
-  nativeBuildInputs = [
-    cmake
-    boost
-    xercesc
-    xalanc
-  ];
-  buildInputs = [
-    qtbase
-    qttools
-    qtmultimedia
-    qtsvg
-  ];
-
-  preConfigure = ''
-    chmod +x configure
-    substituteInPlace configure --replace /bin/bash "${bash}/bin/bash"
-  '';
-
-  meta = with lib; {
-    description = "Open source beer recipe creation tool";
-    mainProgram = "brewtarget";
-    homepage = "http://www.brewtarget.org/";
-    license = licenses.gpl3;
-    maintainers = [ maintainers.mmahut ];
-  };
-}
diff --git a/pkgs/by-name/br/brewtarget/package.nix b/pkgs/by-name/br/brewtarget/package.nix
new file mode 100644
index 000000000000..41fd9fe3cdf7
--- /dev/null
+++ b/pkgs/by-name/br/brewtarget/package.nix
@@ -0,0 +1,66 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  meson,
+  ninja,
+  boost,
+  pandoc,
+  pkg-config,
+  xercesc,
+  xalanc,
+  qt6Packages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "brewtarget";
+  version = "4.0.17";
+
+  src = fetchFromGitHub {
+    owner = "Brewtarget";
+    repo = "brewtarget";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-bJMKmOSoL7mzV7G87O2w1WFWmwRetXa8fUkfLIM5Qwk=";
+    fetchSubmodules = true;
+  };
+
+  postPatch = ''
+    # 3 sed statements from below derived from AUR
+    # Disable boost-stacktrace_backtrace, requires an optional boost lib that's only built in Debianland
+    sed -i "/boostModules += 'stacktrace_backtrace'/ {N;N;d}" meson.build
+    # Make libbacktrace not required, we're not running the bt script
+    sed -i "/compiler\.find_library('backtrace'/ {n;s/true/false/}" meson.build
+    # Disable static linking
+    sed -i 's/static : true/static : false/g' meson.build
+  '';
+
+  nativeBuildInputs = [
+    meson
+    cmake
+    ninja
+    pkg-config
+    qt6Packages.wrapQtAppsHook
+    pandoc
+  ];
+  buildInputs = [
+    boost
+    qt6Packages.qtbase
+    qt6Packages.qttools
+    qt6Packages.qtmultimedia
+    qt6Packages.qtsvg
+    xercesc
+    xalanc
+  ];
+
+  meta = {
+    description = "Open source beer recipe creation tool";
+    mainProgram = "brewtarget";
+    homepage = "http://www.brewtarget.org/";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [
+      avnik
+      mmahut
+    ];
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 31c29debb5ea..0f44a22bd1de 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1788,8 +1788,6 @@ with pkgs;
 
   brakeman = callPackage ../development/tools/analysis/brakeman { };
 
-  brewtarget = libsForQt5.callPackage ../applications/misc/brewtarget { };
-
   # Derivation's result is not used by nixpkgs. Useful for validation for
   # regressions of bootstrapTools on hydra and on ofborg. Example:
   #     pkgsCross.aarch64-multiplatform.freshBootstrapTools.build