diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index eeeba686daf4..1f36e9e858a1 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -6508,6 +6508,13 @@
     githubId = 221929;
     name = "Jean-Baptiste Giraudeau";
   };
+  jboy = {
+    email = "jboy+nixos@bius.moe";
+    githubId = 2187261;
+    github = "jboynyc";
+    matrix = "@jboy:utwente.io";
+    name = "John Boy";
+  };
   jc = {
     name = "Josh Cooper";
     email = "josh@cooper.is";
diff --git a/pkgs/development/compilers/minimacy/default.nix b/pkgs/development/compilers/minimacy/default.nix
new file mode 100644
index 000000000000..0ad4fa0db83e
--- /dev/null
+++ b/pkgs/development/compilers/minimacy/default.nix
@@ -0,0 +1,73 @@
+{ lib, stdenv, fetchFromGitHub, makeBinaryWrapper
+, alsaLib, libX11, libXext, libGL, libGLU
+}:
+
+stdenv.mkDerivation rec {
+  pname = "minimacy";
+  version = "0.6.2";
+
+  src = fetchFromGitHub {
+    owner = "ambermind";
+    repo = pname;
+    rev =  version;
+    sha256 = "i0Z1UKApX+elHmFgujwjiF7k6OmtFF37HJim464OMfU=";
+  };
+
+  nativeBuildInputs = [ makeBinaryWrapper ];
+
+  buildInputs = [ libGL libGLU ] ++ lib.optionals stdenv.isLinux [ alsaLib libX11 libXext ];
+
+  enableParallelBuilding = true;
+
+  NIX_CFLAGS_COMPILE = "-Wno-unused-result";
+
+  preBuild = ''
+    pushd ${if stdenv.isDarwin then "macos/cmdline" else "unix"}
+  '';
+
+  # TODO: build graphic version for darwin
+  buildFlags = (if stdenv.isDarwin then [ "nox" ] else [ "all" ]) ++ [ "CC=${stdenv.cc.targetPrefix}cc" ];
+
+  postBuild = ''
+    popd
+  '';
+
+  doCheck = true;
+
+  checkPhase = ''
+    runHook preCheck
+
+    bin/${if stdenv.isDarwin then "minimacyMac" else "minimacy"} system/demo/demo.fun.mandelbrot.mcy
+
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/lib/minimacy
+    cp -r {README.md,LICENSE,system,rom,topLevel.mcy} $out/lib/minimacy
+    install bin/minimacy* -Dt $out/bin
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    for prog in $out/bin/minimacy*;
+      do wrapProgram $prog \
+        --set MINIMACY $out/lib/minimacy
+      done
+  '';
+
+  meta = {
+    description = "An open-source minimalist computing technology";
+    longDescription = ''
+      Minimacy is an open-source minimalist computation system based on the principle "Less is more".
+      It is designed and programmed by Sylvain Huet.
+    '';
+    maintainers = with lib.maintainers; [ jboy ];
+    homepage    = "https://minimacy.net";
+    license     = lib.licenses.gpl2;
+    platforms   = lib.platforms.linux ++ lib.platforms.darwin;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 7b83a90f9879..fee52fd7bf6c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -15142,6 +15142,8 @@ with pkgs;
 
   microscheme = callPackage ../development/compilers/microscheme { };
 
+  minimacy = callPackage ../development/compilers/minimacy { };
+
   mint = callPackage ../development/compilers/mint { crystal = crystal_1_2; };
 
   mitama-cpp-result = callPackage ../development/libraries/mitama-cpp-result { };