From 13c1993891b44202ed72c508f7627baed4b24a0b Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Ga=C3=ABl=20Reyrol?= <me@gaelreyrol.dev>
Date: Sat, 4 Nov 2023 11:33:04 +0100
Subject: [PATCH] mercure: init at 0.15.5

---
 pkgs/by-name/me/mercure/package.nix | 53 +++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 pkgs/by-name/me/mercure/package.nix

diff --git a/pkgs/by-name/me/mercure/package.nix b/pkgs/by-name/me/mercure/package.nix
new file mode 100644
index 000000000000..e90bd8d10ba4
--- /dev/null
+++ b/pkgs/by-name/me/mercure/package.nix
@@ -0,0 +1,53 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, nix-update-script
+, testers
+, mercure
+}:
+
+buildGoModule rec {
+  pname = "mercure";
+  version = "0.15.5";
+
+  src = fetchFromGitHub {
+    owner = "dunglas";
+    repo = "mercure";
+    rev = "v${version}";
+    hash = "sha256-DyKNKhxjnOfxYcp3w1nB6kxs9c4ZaHL0AN0Eb5vc6mA=";
+  };
+
+  sourceRoot = "source/caddy";
+
+  vendorHash = "sha256-2SZv6iwEZjq/50WwwupfHjbg0vNpff/Cn21nPqeHJMw=";
+
+  subPackages = [ "mercure" ];
+  excludedPackages = [ "../cmd/mercure" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X 'github.com/caddyserver/caddy/v2.CustomVersion=Mercure.rocks v${version} Caddy'"
+  ];
+
+  doCheck = false;
+
+  passthru = {
+    updateScript = nix-update-script { };
+    tests.version = testers.testVersion {
+      version = "v${version}";
+      package = mercure;
+      command = "mercure version";
+    };
+  };
+
+  meta = with lib; {
+    description = "An open, easy, fast, reliable and battery-efficient solution for real-time communications";
+    homepage = "https://github.com/dunglas/mercure";
+    changelog = "https://github.com/dunglas/mercure/releases/tag/v${version}";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [ gaelreyrol ];
+    platforms = platforms.unix;
+    mainProgram = "mercure";
+  };
+}