diff --git a/pkgs/applications/graphics/kphotoalbum/default.nix b/pkgs/applications/graphics/kphotoalbum/default.nix
new file mode 100644
index 000000000000..d32cf9d950c2
--- /dev/null
+++ b/pkgs/applications/graphics/kphotoalbum/default.nix
@@ -0,0 +1,47 @@
+{ mkDerivation
+, fetchurl
+, lib
+, extra-cmake-modules
+, kdoctools
+, wrapGAppsHook
+, exiv2
+, ffmpeg
+, libkdcraw
+, phonon
+, libvlc
+, kconfig
+, kiconthemes
+, kio
+, kinit
+, kpurpose
+}:
+
+mkDerivation rec {
+  pname = "kphotoalbum";
+  version = "5.9.1";
+
+  src = fetchurl {
+    url = "mirror://kde/stable/${pname}/${version}/${pname}-${version}.tar.xz";
+    hash = "sha256-kejzDYpBQEoGKgPzVcUVlGKmd1OoXx+W7t9p3MNNw/A=";
+  };
+
+  # not sure if we really need phonon when we have vlc, but on KDE it's bound to
+  # be on the system anyway, so there is no real harm including it
+  buildInputs = [ exiv2 phonon libvlc ];
+
+  nativeBuildInputs = [ extra-cmake-modules kdoctools wrapGAppsHook ];
+
+  propagatedBuildInputs = [ kconfig kiconthemes kio kinit kpurpose libkdcraw ];
+
+  qtWrapperArgs = [
+    "--prefix PATH : ${lib.makeBinPath [ ffmpeg ]}"
+  ];
+
+  meta = with lib; {
+    description = "Efficient image organization and indexing";
+    homepage = "https://www.kphotoalbum.org/";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ peterhoeg ];
+    inherit (kconfig.meta) platforms;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3b8de739bd09..3528a280d508 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -8060,6 +8060,8 @@ with pkgs;
 
   kpcli = callPackage ../tools/security/kpcli { };
 
+  kphotoalbum = libsForQt5.callPackage ../applications/graphics/kphotoalbum { };
+
   kratos = callPackage ../applications/misc/kratos { };
 
   krename = libsForQt5.callPackage ../applications/misc/krename { };