From ca226cafce2081eed6525674d3c2b1570d2ceae7 Mon Sep 17 00:00:00 2001
From: Gaetan Lepage <gaetan@glepage.com>
Date: Tue, 14 Mar 2023 15:05:41 +0100
Subject: [PATCH] gpu-viewer: init at 2.26

---
 pkgs/applications/misc/gpu-viewer/default.nix | 74 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 76 insertions(+)
 create mode 100644 pkgs/applications/misc/gpu-viewer/default.nix

diff --git a/pkgs/applications/misc/gpu-viewer/default.nix b/pkgs/applications/misc/gpu-viewer/default.nix
new file mode 100644
index 000000000000..9c6f67c5fea3
--- /dev/null
+++ b/pkgs/applications/misc/gpu-viewer/default.nix
@@ -0,0 +1,74 @@
+{ lib
+, fetchFromGitHub
+, pkg-config
+, meson
+, ninja
+, gtk4
+, libadwaita
+, python3Packages
+, gobject-introspection
+, vulkan-tools
+, python3
+, wrapGAppsHook
+, gdk-pixbuf
+, lsb-release
+, glxinfo
+, vdpauinfo
+, clinfo
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "gpu-viewer";
+  version = "2.26";
+
+  format = "other";
+
+  src = fetchFromGitHub {
+    owner = "arunsivaramanneo";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-3GYJq76g/pU8dt+OMGBeDcw47z5Xv3AGkLsACcBCELs=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    meson
+    ninja
+    gobject-introspection
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk4
+    libadwaita
+    vulkan-tools
+    gdk-pixbuf
+  ];
+
+  pythonPath = with python3Packages; [
+    pygobject3
+    click
+  ];
+
+  # Prevent double wrapping
+  dontWrapGApps = true;
+
+  postFixup = ''
+    makeWrapper ${python3.interpreter} $out/bin/gpu-viewer \
+      --prefix PATH : "${lib.makeBinPath [ clinfo glxinfo lsb-release vdpauinfo vulkan-tools ]}" \
+      --add-flags "$out/share/gpu-viewer/Files/GPUViewer.py" \
+      --prefix PYTHONPATH : "$PYTHONPATH" \
+      --chdir "$out/share/gpu-viewer/Files" \
+      ''${makeWrapperArgs[@]} \
+      ''${gappsWrapperArgs[@]}
+  '';
+
+
+  meta = with lib; {
+    homepage = "https://github.com/arunsivaramanneo/GPU-Viewer";
+    description = "A front-end to glxinfo, vulkaninfo, clinfo and es2_info";
+    maintainers = with maintainers; [ GaetanLepage ];
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 9b5ef1079c13..50810c1058ae 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -4946,6 +4946,8 @@ with pkgs;
     stdenv = gcc9Stdenv;
   };
 
+  gpu-viewer = callPackage ../applications/misc/gpu-viewer { };
+
   greg = callPackage ../applications/audio/greg {
     pythonPackages = python3Packages;
   };