diff --git a/pkgs/by-name/un/unicodeit/package.nix b/pkgs/by-name/un/unicodeit/package.nix
new file mode 100644
index 000000000000..c9abda9386aa
--- /dev/null
+++ b/pkgs/by-name/un/unicodeit/package.nix
@@ -0,0 +1,5 @@
+{
+  python3Packages,
+}:
+with python3Packages;
+toPythonApplication unicodeit
diff --git a/pkgs/development/python-modules/unicodeit/default.nix b/pkgs/development/python-modules/unicodeit/default.nix
new file mode 100644
index 000000000000..30372a2c8e83
--- /dev/null
+++ b/pkgs/development/python-modules/unicodeit/default.nix
@@ -0,0 +1,61 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  fetchpatch,
+  pytestCheckHook,
+  runCommand,
+
+  setuptools,
+  unicodeit,
+}:
+buildPythonPackage rec {
+  pname = "unicodeit";
+  version = "0.7.5";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "svenkreiss";
+    repo = "unicodeit";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-NeR3fGDbOzwyq85Sep9KuUiARCvefN6l5xcb8D/ntHE=";
+  };
+
+  patches = [
+    (fetchpatch {
+      # Defines a CLI entry point, so `setuptools` generates an `unicodeit` executable
+      url = "https://github.com/svenkreiss/unicodeit/pull/79/commits/9f4a4fee5cb62a101075adf3054832cdb1e6a5ad.patch";
+      hash = "sha256-mAhmU17K0adEFFAIf7ZeJ/cNohrzrL+sol7gYfWbPGo=";
+    })
+  ];
+
+  build-system = [ setuptools ];
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  pythonImportsCheck = [
+    "unicodeit"
+    "unicodeit.cli"
+  ];
+
+  passthru.tests.entrypoint =
+    runCommand "python3-unicodeit-test-entrypoint"
+      {
+        nativeBuildInputs = [ unicodeit ];
+        preferLocalBuild = true;
+      }
+      ''
+        [[ "$(unicodeit "\BbbR")" = "ℝ" ]]
+        touch $out
+      '';
+
+  meta = {
+    description = "Converts LaTeX tags to unicode";
+    mainProgram = "unicodeit";
+    homepage = "https://github.com/svenkreiss/unicodeit";
+    license = with lib.licenses; [
+      lppl13c
+      mit
+    ];
+    maintainers = with lib.maintainers; [ nicoo ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 42929bc9020f..75add18afc85 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -16809,6 +16809,8 @@ self: super: with self; {
 
   unicodedata2 = callPackage ../development/python-modules/unicodedata2 { };
 
+  unicodeit = callPackage ../development/python-modules/unicodeit { };
+
   unicode-rbnf = callPackage ../development/python-modules/unicode-rbnf { };
 
   unicode-slugify = callPackage ../development/python-modules/unicode-slugify { };