From e0a0f4f1f7ed5accae8b8d902b387a5d77cd5506 Mon Sep 17 00:00:00 2001
From: Mutsuha Asada <me@momee.mt>
Date: Fri, 4 Oct 2024 02:04:20 +0900
Subject: [PATCH] almo: init at 0.9.5-alpha (#343864)

almo: init at 0.9.5-alpha
---
 pkgs/by-name/al/almo/package.nix | 51 ++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/al/almo/package.nix

diff --git a/pkgs/by-name/al/almo/package.nix b/pkgs/by-name/al/almo/package.nix
new file mode 100644
index 000000000000..00764f5301a7
--- /dev/null
+++ b/pkgs/by-name/al/almo/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenv,
+  gcc,
+  python312Packages,
+}:
+let
+  version = "0.9.5-alpha";
+in
+stdenv.mkDerivation {
+  pname = "almo";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "abap34";
+    repo = "almo";
+    rev = "refs/tags/v${version}";
+    sha256 = "sha256-Cz+XDJmdp+utzwm1c7ThTNS6kfNF6r4B16tnGQSCVMc=";
+  };
+
+  buildInputs = [
+    gcc
+    python312Packages.pybind11
+  ];
+
+  makeFlags = [ "all" ];
+
+  # remove darwin-only linker flag on linux
+  postPatch = lib.optionalString (!stdenv.isDarwin) ''
+    substituteInPlace scripts/pybind.sh \
+      --replace-fail " -undefined dynamic_lookup" ""
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin $out/lib
+    cp build/almo $out/bin
+    cp almo.so $out/lib
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "ALMO is markdown parser and static site generator";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.all;
+    homepage = "https://github.com/abap34/almo";
+    maintainers = with lib.maintainers; [ momeemt ];
+    mainProgram = "almo";
+  };
+}