From c6f020810df0f3cba17f03f488179af1a00f424d Mon Sep 17 00:00:00 2001
From: Sped0n <hi@sped0n.com>
Date: Sat, 17 Jan 2026 15:21:31 +0800
Subject: [PATCH 1/2] maintainers: add Sped0n

Signed-off-by: Sped0n <hi@sped0n.com>
---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index ef50ebc387ae..ff9c3c7220aa 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -24916,6 +24916,12 @@
     github = "spectre256";
     githubId = 72505298;
   };
+  Sped0n = {
+    name = "Ryan Wen";
+    email = "hi@sped0n.com";
+    github = "Sped0n";
+    githubId = 197479310;
+  };
   spencerjanssen = {
     email = "spencerjanssen@gmail.com";
     matrix = "@sjanssen:matrix.org";

From f6f584bf3060fb81a389f21bd926726db36a436d Mon Sep 17 00:00:00 2001
From: Sped0n <hi@sped0n.com>
Date: Sat, 17 Jan 2026 15:27:31 +0800
Subject: [PATCH 2/2] diun: init at 4.31.0

Signed-off-by: Sped0n <hi@sped0n.com>
---
 pkgs/by-name/di/diun/package.nix | 67 ++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 pkgs/by-name/di/diun/package.nix

diff --git a/pkgs/by-name/di/diun/package.nix b/pkgs/by-name/di/diun/package.nix
new file mode 100644
index 000000000000..8a492b58ecbf
--- /dev/null
+++ b/pkgs/by-name/di/diun/package.nix
@@ -0,0 +1,67 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+  versionCheckHook,
+}:
+buildGoModule (finalAttrs: {
+  pname = "diun";
+  version = "4.31.0";
+
+  src = fetchFromGitHub {
+    owner = "crazy-max";
+    repo = "diun";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-H05yZSH2rUrwM+ZR/PDCxXmrDkZ/Gd4RrpywGk5eW2A=";
+  };
+  vendorHash = null;
+
+  # upstream disable CGO in release build
+  # https://github.com/crazy-max/diun/blob/76c0fe99212adc58d6a3433bbcde1ffa9fb879c4/Dockerfile#L11
+  env.CGO_ENABLED = false;
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X"
+    "main.version=${finalAttrs.version}"
+  ];
+
+  checkFlags =
+    let
+      # these tests require a network connection
+      skippedTests = [
+        "TestTags"
+        "TestTagsWithDigest"
+        "TestCompareDigest"
+        "TestManifest"
+        "TestManifestMultiUpdatedPlatform"
+        "TestManifestMultiNotUpdatedPlatform"
+        "TestManifestVariant"
+        "TestManifestTaggedDigest"
+        "TestManifestTaggedDigestUnknownTag"
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  doInstallCheck = true;
+
+  postInstall = ''
+    mv $out/bin/cmd $out/bin/diun
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "CLI application to receive notifications when a Docker image is updated on a Docker registry";
+    homepage = "https://crazymax.dev/diun";
+    changelog = "https://crazymax.dev/diun/changelog";
+    license = lib.licenses.mit;
+    mainProgram = "diun";
+    maintainers = with lib.maintainers; [ Sped0n ];
+    platforms = lib.platforms.unix;
+  };
+})