From d19f33e39448426cb2e159b78df79e65b5437299 Mon Sep 17 00:00:00 2001
From: Pol Dellaiera <pol.dellaiera@protonmail.com>
Date: Mon, 6 Oct 2025 10:56:29 +0200
Subject: [PATCH] ete: init at 0-unstable-2025-08-17

---
 pkgs/by-name/et/ete/package.nix | 48 +++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 pkgs/by-name/et/ete/package.nix

diff --git a/pkgs/by-name/et/ete/package.nix b/pkgs/by-name/et/ete/package.nix
new file mode 100644
index 000000000000..850b8f115503
--- /dev/null
+++ b/pkgs/by-name/et/ete/package.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  symlinkJoin,
+  etlegacy-assets,
+  ete-unwrapped,
+  makeBinaryWrapper,
+}:
+
+symlinkJoin {
+  pname = "ete";
+  version = ete-unwrapped.version;
+
+  paths = [
+    (etlegacy-assets.overrideAttrs (prev: {
+      postInstall = (prev.postInstall or "") + ''
+        mv $out/lib/etlegacy $out/lib/ete
+      '';
+    }))
+    ete-unwrapped
+  ];
+
+  nativeBuildInputs = [
+    makeBinaryWrapper
+  ];
+
+  postBuild = ''
+    wrapProgram $out/bin/ete.* \
+      --add-flags "+set fs_basepath ${placeholder "out"}/lib/ete"
+    wrapProgram $out/bin/ete-ded.* \
+      --add-flags "+set fs_basepath ${placeholder "out"}/lib/ete"
+  '';
+
+  meta = {
+    description = "Improved Wolfenstein: Enemy Territory Engine";
+    homepage = "https://github.com/etfdevs/ETe";
+    license = with lib.licenses; [
+      gpl3Plus
+      cc-by-nc-sa-30
+    ];
+    mainProgram = "ete." + (if stdenv.hostPlatform.isi686 then "x86" else "x86_64");
+    maintainers = with lib.maintainers; [
+      ashleyghooper
+      drupol
+    ];
+    platforms = lib.platforms.linux;
+  };
+}