From 234be397d65393c16d562fda3f397c6de6fd2510 Mon Sep 17 00:00:00 2001
From: Azat Bahawi <azat@bahawi.net>
Date: Tue, 5 Jul 2022 21:42:16 +0300
Subject: [PATCH] xprompt: init at 2.5.0

---
 pkgs/tools/X11/xprompt/default.nix | 56 ++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix    |  2 ++
 2 files changed, 58 insertions(+)
 create mode 100644 pkgs/tools/X11/xprompt/default.nix

diff --git a/pkgs/tools/X11/xprompt/default.nix b/pkgs/tools/X11/xprompt/default.nix
new file mode 100644
index 000000000000..69149b3889b8
--- /dev/null
+++ b/pkgs/tools/X11/xprompt/default.nix
@@ -0,0 +1,56 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, writeText
+, fontconfig
+, libX11
+, libXft
+, libXinerama
+, conf ? null
+, nix-update-script
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xprompt";
+  version = "2.5.0";
+
+  src = fetchFromGitHub {
+    owner = "phillbush";
+    repo = "xprompt";
+    rev = "v${version}";
+    sha256 = "sha256-pOayKngUlrMY3bFsP4Fi+VsOLKCUQU3tdkZ+0OY1SCo=";
+  };
+
+  buildInputs = [
+    fontconfig
+    libX11
+    libXft
+    libXinerama
+  ];
+
+  postPatch = with lib;
+    let
+      configFile =
+        if isDerivation conf || builtins.isPath conf
+        then conf else writeText "config.h" conf;
+    in
+    optionalString (conf != null) "cp ${configFile} config.h";
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  passthru.updateScript = nix-update-script {
+    attrPath = pname;
+  };
+
+  meta = with lib; {
+    description = "A dmenu rip-off with contextual completion";
+    longDescription = ''
+      XPrompt is a prompt for X. XPrompt features a text input field where the
+      user can type in a text subject to tab-completion.
+    '';
+    homepage = "https://github.com/phillbush/xprompt";
+    license = licenses.mit;
+    maintainers = with maintainers; [ azahi ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index c79431daf6bc..649a11abd53e 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -11842,6 +11842,8 @@ with pkgs;
 
   xfstests = callPackage ../tools/misc/xfstests { };
 
+  xprompt = callPackage ../tools/X11/xprompt { };
+
   xprintidle = callPackage ../tools/X11/xprintidle {};
 
   xprintidle-ng = callPackage ../tools/X11/xprintidle-ng {};