From 020fe13bf92e3cd147522f7b7f45e259cd65b6ef Mon Sep 17 00:00:00 2001
From: Andrew Gigena <mail@andrewgigena.dev>
Date: Thu, 19 Jun 2025 23:50:14 -0300
Subject: [PATCH 1/2] maintainers: add andrewgigena

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 7724dd513143..b41201df8433 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -1606,6 +1606,12 @@
     githubId = 7644264;
     name = "Andrew Gazelka";
   };
+  andrewgigena = {
+    email = "work@andrewgigena.dev";
+    github = "andrewgigena";
+    githubId = 37125554;
+    name = "Andrew Gigena";
+  };
   AndrewKvalheim = {
     email = "andrew@kvalhe.im";
     github = "AndrewKvalheim";

From 3045fea7110e80f5cda7b2beb2405cd740d04ea8 Mon Sep 17 00:00:00 2001
From: Andrew Gigena <mail@andrewgigena.dev>
Date: Sun, 22 Jun 2025 01:20:47 -0300
Subject: [PATCH 2/2] opencl-caps-viewer: init at 1.20

---
 .../by-name/op/opencl-caps-viewer/package.nix | 73 +++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 pkgs/by-name/op/opencl-caps-viewer/package.nix

diff --git a/pkgs/by-name/op/opencl-caps-viewer/package.nix b/pkgs/by-name/op/opencl-caps-viewer/package.nix
new file mode 100644
index 000000000000..bff2baab4143
--- /dev/null
+++ b/pkgs/by-name/op/opencl-caps-viewer/package.nix
@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  ocl-icd,
+  opencl-headers,
+  libsForQt5,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "opencl-caps-viewer";
+  version = "1.20";
+
+  src = fetchFromGitHub {
+    owner = "SaschaWillems";
+    repo = "OpenCLCapsViewer";
+    tag = finalAttrs.version;
+    hash = "sha256-P7G8FvVXzDAfN3d4pGXC+c9x4bY08/cJNYQ6lvjyVCQ=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    libsForQt5.qmake
+    libsForQt5.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    ocl-icd
+    opencl-headers
+    libsForQt5.qtx11extras
+    libsForQt5.qtbase
+  ];
+
+  postPatch = ''
+    # Fix installation paths
+    substituteInPlace OpenCLCapsViewer.pro \
+      --replace-fail "target.path = /usr/bin" "target.path = /bin/" \
+      --replace-fail "desktop.path = /usr/share/applications" "desktop.path = /share/applications" \
+      --replace-fail "icon.path = /usr/share/icons/hicolor/256x256/apps/" "icon.path = /share/icons/hicolor/256x256/apps/" \
+      --replace-fail 'else: unix:!android: target.path = /opt/$${TARGET}/bin' ""
+  '';
+
+  qmakeFlags = [
+    "OpenCLCapsViewer.pro"
+    "CONFIG+=x11"
+  ];
+
+  installFlags = [ "INSTALL_ROOT=${placeholder "out"}" ];
+
+  postInstall = ''
+    cp Resources/icon.png $out/share/icons/hicolor/256x256/apps/openclCapsViewer.png
+  '';
+
+  qtWrapperArgs = [
+    "--prefix LD_LIBRARY_PATH : ${ocl-icd}/lib"
+  ];
+
+  enableParallelBuilding = true;
+
+  meta = {
+    mainProgram = "OpenCLCapsViewer";
+    description = "OpenCL hardware capability viewer";
+    longDescription = ''
+      Client application to display hardware implementation details for devices supporting the OpenCL API by Khronos.
+      The hardware reports can be submitted to a public online database that allows comparing different devices, browsing available features, extensions, formats, etc.
+    '';
+    homepage = "https://opencl.gpuinfo.org/";
+    platforms = lib.platforms.linux;
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ andrewgigena ];
+    changelog = "https://github.com/SaschaWillems/OpenCLCapsViewer/releases/tag/${finalAttrs.version}";
+  };
+})