From 0e957e0933ee641fb6f8b810613b584152c3808e Mon Sep 17 00:00:00 2001
From: pancaek <20342389+pancaek@users.noreply.github.com>
Date: Fri, 20 Feb 2026 20:14:27 -0800
Subject: [PATCH] cine: init at 1.0.9

---
 pkgs/by-name/ci/cine/package.nix | 72 ++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 pkgs/by-name/ci/cine/package.nix

diff --git a/pkgs/by-name/ci/cine/package.nix b/pkgs/by-name/ci/cine/package.nix
new file mode 100644
index 000000000000..5eb44bf9bd0a
--- /dev/null
+++ b/pkgs/by-name/ci/cine/package.nix
@@ -0,0 +1,72 @@
+{
+  lib,
+  fetchFromGitHub,
+  cmake,
+  meson,
+  ninja,
+  wrapGAppsHook4,
+  appstream,
+  blueprint-compiler,
+  desktop-file-utils,
+  gettext,
+  glib,
+  gtk4,
+  libadwaita,
+  libGL,
+  pkg-config,
+  python3Packages,
+}:
+
+python3Packages.buildPythonApplication (finalAttrs: {
+  pname = "cine";
+  version = "1.0.9";
+  pyproject = false;
+
+  src = fetchFromGitHub {
+    owner = "diegopvlk";
+    repo = "Cine";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-aw+M1wCGSbRRmKKcgyM4luEr0WtPLw/v7SqBE1B5H9U=";
+    fetchSubmodules = true;
+  };
+
+  strictDeps = true;
+  dontWrapGApps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    cmake
+    pkg-config
+    wrapGAppsHook4
+    blueprint-compiler
+    desktop-file-utils
+    appstream
+  ];
+
+  buildInputs = [
+    gettext
+    glib
+    gtk4
+    libadwaita
+  ];
+
+  dependencies = with python3Packages; [
+    pygobject3
+    mpv
+  ];
+
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+    makeWrapperArgs+=(--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ libGL ]})
+  '';
+
+  meta = {
+    description = "Video Player for Linux";
+    homepage = "https://github.com/diegopvlk/Cine";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ pancaek ];
+    mainProgram = "cine";
+    platforms = lib.platforms.linux;
+  };
+})